_prefix_footnote.ado

来自「是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到」· ADO 代码 · 共 43 行

*! version 1.0.6  30mar2005
program _prefix_footnote
	version 9
	syntax [, deff ]

	local footnote `"`e(footnote)'"'
	gettoken cmd args : footnote, parse(" ,")
	capture which `cmd'
	if !c(rc) {
		`footnote'
	}
	if "`e(prefix)'" == "svy" {
		_svy_fpc_note `deff'
		_svy_subpop_note
		_svy_singleton_note
	}
	if "`e(missing)'" == "missing" ///
	 & inlist("`e(vce)'", "brr", "bootstrap", "jackknife") {
	 	if "`e(vce)'" == "brr" {
			local vcetype BRR
		}
		else	local vcetype `e(vce)'
		if e(N_misreps) == 1 {
			local reps replicate
		}
		else {
			local reps replicates
		}
		if "`e(N_misreps)'" != "" {
			local the `e(N_misreps)'
		}
		else	local the "some of the"
		di as txt "{p 0 6 2}" ///
"Note: One or more parameters could not be estimated in " ///
"`the' `vcetype' `reps'; " ///
"standard error estimates include only complete replications.{p_end}"
	}
	if `"`e(opt)'"' == "ml" | !missing(e(converged)) {
		ml_footnote
	}
end
exit