_get_eformopts.ado

来自「是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到」· ADO 代码 · 共 53 行

*! version 1.0.1  27feb2005
program define _get_eformopts, sclass
	version 8.0
	syntax [, eformopts(string asis) soptions ALLOWed(string) ]
	local 0 , `eformopts'

	if "`allowed'" == "__all__" {
		local allowed NOHR hr or IRr RRr
	}
	foreach ef of local allowed {
		capture confirm name `ef'
		if _rc {
			di as err "`ef' is not a valid name"
			exit 198
		}
		local efopts `efopts' `=lower("`ef'")'
	}
	if "`soptions'" != "" {
		syntax [, EForm1(string) EForm `allowed' * ]
	}
	else	syntax [, EForm1(string) EForm `allowed' ]

	foreach ef of local efopts {
		local eform `eform' ``ef''
	}
	local k : word count `eform'
	if `k' > 1 {
		local eform : list retok eform
		di as err `"options '`eform'' may not be combined"'
		exit 198
	}
	if `"`eform1'"' != "" & `k' {
		di as err "options `eform' and eform() may not be combined"
		exit 198
	}
	if `k' {
		     if ("`eform'"=="eform") local eform1 = "exp(b)"
		else if ("`eform'"=="hr")    local eform1 = "Haz. Ratio"
		else if ("`eform'"=="or")    local eform1 = "Odds Ratio"
		else if ("`eform'"!="nohr")  local eform1 = upper("`eform'")
	}
	sreturn clear
	sreturn local options `"`options'"'
	sreturn local opt `eform'
	sreturn local str `eform1'
	if `"`eform1'"' != "" {
		sreturn local eform eform(`"`eform1'"')
	}
	else	sreturn local eform ""
end

exit