_ca_parse_normalize.ado

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

*! version 1.0.0  06jul2004
program _ca_parse_normalize, sclass
	version 8
	
	local 0 ,`0' 
	
	syntax [, CAnonical SYmmetric ROw COlumn PRincipal * ]
	
	local opt  `canonical' `symmetric' `row' `column' `principal'
	local nopt : list sizeof opt
	if `nopt' > 1 {
		opts_exclusive "`opt'" normalize 198
	}	
	else if `nopt' == 1 & `"`options'"' != "" { 
		dis as err "normalize() invalid; unexpected input `options'"' 
		exit 198
	}
	else if `"`options'"' != "" { 
		local opt value
		numlist "`options'", range(>=0 <=1) max(1)
		local value = `r(numlist)'
		local opt "value=`value'" 
	}
	else if inlist("`opt'", "symmetric", "canonical", "") { 
		local opt symmetric
		local value = 0.5
	}
	else if "`opt'" == "row" {
		local value = 1
	}
	else if "`opt'" == "column" {
		local value = 0
	}
	
	sreturn clear
	sreturn local normalize `opt' 
	
	if "`opt'" == "principal" {
		sreturn local alpha = 1
		sreturn local beta  = 1
	}
	else { 
		sreturn local alpha = `value' 
		sreturn local beta  = 1 - `value' 
	}	
end
exit