_svy_setup.ado

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

*! version 1.1.5  01apr2005
program _svy_setup, rclass
	version 9
	syntax [anything] [pw iw] [, SVY * ]
	if "`svy'" == "" {
		syntax [anything] [pw iw] [,		///
			cmdname(name)			///
			over(passthru)			///
		]
	}
	else {
		syntax [anything] [pw iw] [,		///
			cmdname(name)			///
			SVY				///
			BRR				///
			JACKknife JKNIFE		///
			hasover				///
			over(passthru)			///
			SUBpop(passthru)		///
			SRSsubpop			///
			noSUBDROP			///
			VCE(string)			///
		]
	}

	if "`jknife'" != "" {
		local jackknife jackknife
	}

	local kex : word count `brr' `jackknife'
	if `"`vce'"' != "" {
		local ++kex
	}
	if `kex' > 1 {
		opts_exclusive "brr jackknife vce()" vce
	}

	local nvars : word count `anything'
	if `nvars' != 2 {
		local 0 `anything'
		syntax namelist(min=2 max=2)
	}
	confirm name `anything'
	tokenize `anything'
	args	touse		/// already exists
		subuse		// new variable

	if "`svy'" != "" {
		if `"`weight'"' != "" {
			di as err ///
		"weights can only be supplied to {help svyset##|_new:svyset}"
			exit 198
		}
		quietly svyset
		if "`r(settings)'" == ", clear" {
	di as err "data not set up for svy, use {help svyset##|_new:svyset}"
			exit 119
		}
		if "`r(wtype)'" != "" {
			local wvar `"`r(wexp)'"'
			gettoken equal wvar : wvar, parse(" =")
			if "`equal'" != "=" {
				di as err "invalid svyset"
				exit 459
			}
		}
		local numvars `wvar' `r(postweight)'
		local strvars `r(poststrata)'
		local stages = cond(missing(r(stages)), 0, r(stages))
		forval i = 1/`stages' {
			if "`r(su`i')'" != "_n" {
				local su `r(su`i')'
			}
			else	local su
			local strvars	`strvar' `r(strata`i')' `su'
			local numvars	`numvars' `r(fpc`i')'
		}
		return add
		return local settings
		markout `touse' `numvars'
		markout `touse' `strvars', strok
		_svy_check_postw `touse' "`r(poststrata)'" "`r(postweight)'"
	}

	// identify subpopulation observations
	_svy_subpop `touse' `subuse',		///
		`over'				///
		`hasover'			///
		`subpop'			///
		wvar(`wvar')			///
		strata(`return(strata)')	///
		`subdrop'			///
		// blank
	return add

	if "`cmdname'" != "tabulate" {
		// only -svy:tabulate- cares about the -srssubpop- option
		return local srssubpop
	}

	if "`return(wtype)'" == "pweight" {
		quietly count if `wvar' < 0
		if r(N) {
			error 402
		}
	}

end
exit