_r2e.ado

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

*! version 1.0.1  03jan2005
program _r2e, eclass
	version 9
	syntax [,			///
		XMACros(namelist)	///
		XSCAlars(namelist)	///
		XMATrices(namelist)	///
	]

	// This routine assumed that e() is ready to have things added to it,
	// meaning that -ereturn post- has already been called.

	// save the macros
	local macros : r(macros)
	local macros : list macros - xmacros
	foreach name of local macros {
		ereturn local `name' `"`r(`name')'"'
	}

	// save the scalars
	local scalars : r(scalars)
	local scalars : list scalars - xscalars
	foreach name of local scalars {
		ereturn scalar `name' = r(`name')
	}

	// save the matrices
	local bV b V		// never allow mis-post of e(b) e(V)
	local matrices : r(matrices)
	local matrices : list matrices - xmatrices
	local matrices : list matrices - bV
	tempname mat
	foreach name of local matrices {
		matrix `mat' = r(`name')
		ereturn matrix `name' `mat'
	}

	ClearR
end

program ClearR, rclass
	return clear
end
exit