_prefix_model_test.ado

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

*! version 1.0.2  25feb2005
program _prefix_model_test, eclass
	version 9
	syntax [name(name=cmd)] [, svy noADJust noSVYadjust ]

	if "`cmd'" == "mlogit" {
		local coleq : coleq e(b), quote
		local K : word count `: list uniq coleq'
		forval i = 1/`K' {
			local spec "`spec' ([#`i'])"
		}
	}
	else	local spec "([#1])"

	// look for constraints
	tempname cns
	capture matrix `cns' = get(Cns)
	if (c(rc)) local cns

	if "`svy'" != "" & "`adjust'`svyadjust'" != "" {
		local adjust nosvyadjust
	}
	else	local adjust

	capture test `spec', `adjust'
	if !c(rc) {
		ereturn scalar df_m = r(df)
		if r(drop) == 0 | "`cns'" != "" {
			if !missing(e(df_r)) {
				ereturn scalar F = r(F)
			}
			else {
				ereturn scalar chi2 = r(chi2)
				ereturn local chi2type Wald
			}
			ereturn scalar p = r(p)
		}
		else {
			if !missing(e(df_r)) {
				ereturn scalar F = .
			}
			else {
				ereturn scalar chi2 = .
				ereturn local chi2type Wald
			}
			ereturn scalar p = .
		}
	}
	else {
		if missing(e(df_r)) {
			ereturn local chi2type Wald
		}
		ereturn scalar df_m = 0
	}
end