gboxopt_98.idlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  gboxopt_98.idlg include file for graph box options
  **Special version for Windows95/98
  
*!  VERSION 1.0.2  22mar2005

*/

DIALOG gboxopt, label("") /*
		*/ tabtitle("Misc.")
BEGIN
  TEXT     tx_disp     _lft        _top      155         .,		/*
  		*/ label("Horizontal/vertical display:") right
  COMBOBOX cb_disp     +165        @         _txlr4g     .,		/*
  		*/ label("Horizontal/vertical display") dropdownlist	/*
  		*/contents(display) values(displayv)
  GROUPBOX gb_boxopts  _lft        _ls       _gwd1       _ht2, 		/*
		*/ label("Box options") 
DEFINE holdy @y
  CHECKBOX ck_nofill   _igft       _ss       _gwd2       .,		/*
  		*/ label("Omit empty categories ") 			/*
  		*/ option(nofill)
  		
  GROUPBOX gb_missing  _lft        _xls      _gwd1       _ht6,		/*
  		*/ label("Missing values")
  CHECKBOX ck_miss     _igft       _ss       _gwd2       .,		/*
  		*/ label("Include categories for missing values")	/*
  		*/ option(missing)
  CHECKBOX ck_cw       @           _ms       @           .,		/*
		*/ label("Exclude observations with missing values ") /* 
		*/ option(cw) 
  TEXT     tx_cw       _cksep      _vss      _inwd       .,		/*
  		*/ label("(casewise deletion)") 
  GROUPBOX gb_ybar     _lft        _xls      _gwd1       _ht5,		/*
  		*/ label("Labeling and legend options")
  CHECKBOX ck_ascat    _igft       _ss       _gwd2       .,		/*
  		*/ label("Treat Y-variables as first over() group")	/*
  		*/ option(ascategory)
  CHECKBOX ck_asyvars  @           _ms       @           .,		/*
  		*/ label("Treat first over() group as Y-variables")	/*
  		*/ option(asyvars)
  		
  GROUPBOX gb_size     _lft2g      holdy     _gwd1       _ht6,		/*
  		*/ label("Adjacent line size options")
  TEXT     tx_alsize   _igft2	   _ms	     _txwd       .,		/*
  		*/ label("Width:")					/*
  		*/ right
  EDIT     ed_alsize   _txsep      @         _txr4gi     .,             /*
  		*/ option(alsize)					/*
  		*/ label("Width of adjacent line")			/*
  		*/ default("67")					/*
  		*/ numonly
  TEXT     tx_capsize  _igft2	   _ls	     _txwd       .,		/*
  		*/ label("Height:")					/*
  		*/ right
  EDIT     ed_capsize  _txsep      @         _txr4gi     .,             /*
  		*/ option(capsize)					/*
  		*/ label("Width of adjacent line")			/*
  		*/ default("0")						/*
  		*/ numonly
  CHECKBOX ck_whisk    _lft2g      _xxls     _gwd1       _ht10h,	/*
  		*/ label("Use custom whiskers")				/*
  		*/ groupbox						/*
  		*/ option(cwhiskers)					/*
  		*/ clickon(program gboxopt_whisk_check)			/*
  		*/ clickoff(program gboxopt_whisk_check)
  CHECKBOX ck_lclr     _igft2      _ls       _txwd       .,		/*
  		*/ label("Color") 					/*
  		*/ clickon(gaction gboxopt.cl_lclr.show)		/*
  		*/ clickoff(gaction gboxopt.cl_lclr.hide)
  COLOR    cl_lclr     _txsep      @         _txr4gi    .,		/*
  		*/ option(lcolor)
  TEXT     tx_lpat     _igft2      _ls       _txwd       .,		/*
  		*/ label("Pattern:") 					/*
  		*/ right
  COMBOBOX cb_lpat     _txsep      @         _txr4gi     .,		/*
  		*/ contents(linepatterns) option(lpattern) dropdownlist
  TEXT     tx_lwd      _igft2      _ls       _txwd       .,		/*
  		*/ label("Width:") 					/*
  		*/ right
  COMBOBOX cb_lwd      _txsep      @         _txr4gi     .,		/*
  		*/ option(lwidth) contents(linewidths) dropdownlist
END

LIST display
BEGIN
	Default
	Horizontal
	Vertical
END

LIST displayv
BEGIN
	""
	horizontal
	vertical
END

PROGRAM gboxopt_whisk_check
BEGIN
	if !H(gboxopt.ck_whisk) {
		if gboxopt.ck_whisk {
			call gaction gboxopt.ck_lclr.enable
			call gaction gboxopt.cl_lclr.enable
			call gaction gboxopt.tx_lpat.enable
			call gaction gboxopt.cb_lpat.enable
			call gaction gboxopt.tx_lwd.enable
			call gaction gboxopt.cb_lwd.enable
		}
		if !gboxopt.ck_whisk {
			call gaction gboxopt.ck_lclr.disable
			call gaction gboxopt.cl_lclr.disable
			call gaction gboxopt.tx_lpat.disable
			call gaction gboxopt.cb_lpat.disable
			call gaction gboxopt.tx_lwd.disable
			call gaction gboxopt.cb_lwd.disable
		}
	}
END

PROGRAM gboxopt_lines_pr
BEGIN
	if !H(gboxopt.cl_lclr) {
		optionarg /quoted gboxopt.cl_lclr
	}
	optionarg gboxopt.cb_lpat
	optionarg gboxopt.cb_lwd
END

PROGRAM gboxopt_output
BEGIN
	put gboxopt.cb_disp
	option gboxopt.ck_nofill
	option gboxopt.ck_miss
	option gboxopt.ck_ascat
	option gboxopt.ck_asyvars
	option gboxopt.ck_cw
	optionarg /hidedefault gboxopt.ed_alsize
	optionarg /hidedefault gboxopt.ed_capsize
	option gboxopt.ck_whisk
	if gboxopt.ck_whisk {
		if !H(gboxopt.cl_lclr) | gboxopt.cb_lpat | gboxopt.cb_lwd {
		   	put " " "lines("
		   	put /program gboxopt_lines_pr
		   	put ") "
		}
	}
END