gdotline_98.idlg

来自「是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到」· IDLG 代码 · 共 264 行

/*
  gdotline_98.idlg -- include file for linelook options on graph dot
  **Special version for Windows95/98
  
  VERSION 1.0.0  21dec2002

*/

DIALOG gdl, label("") 							/*
		*/ tabtitle("Lines")
BEGIN
  /*--+----1----+----2----+----3----+----4----+----5----+----6----+----7----+*/ 
  GROUPBOX gb_linetype     _lft       _top      _gwd4_1   _ht6,		/*
  		*/label("Line type:")
  RADIO    rb_dot          _ilft      _ss       _cwd4_3   .,		/*
  		*/label("Dot") first option("linetype(dot)") 		/*
  		*/clickon(script gdl_doton)
  RADIO    rb_line         @          _ss       @         .,		/*
  		*/label("Line") option("linetype(line)") 		/*
  		*/clickon(script gdl_lineon)
  RADIO    rb_rect         @          _ss       @         .,		/*
  		*/label("Rectangle") option("linetype(rectangle)")	/*
  		*/last clickon(script gdl_recton)
  TEXT     tx_ogap         _gft4_2    _top      _txwd     .,		/*
		*/label("Outer gap:") right
  EDIT     ed_ogap         _txsep     @         _txr4g    .,		/*
  		*/label("Outer gap") numonly option(outergap)
  TEXT     tx_linegap      _gft4_2    _ls       _txwd     .,		/*
  		*/label("Line gap:") right
  EDIT     en_linegap      _txsep     @         _txr4g    .,		/*
  		*/label("Line gap") numonly default(0) option(linegap)
  TEXT     tx_extend       _gft4_2    _ls       _txwd     .,		/*
  		*/label("Extend line:") right
  COMBOBOX cb_extend       _txsep     @         _txr4g    .,		/*
  		*/label("Extend line") contents(_dclst_13)		/*
  		*/value(gdl_extend) dropdownlist			/*
		*/onselchangelist(gdl_extend_change)
  TEXT     tx_lowext       _gft4_3    _top      _gwd4_1   .,		/*
  		*/label("Low extension:") right
  EDIT     ed_lowext       _gft4_4    @         _en7wd    .,		/*
  		*/label("Low extension")  option(lowextension)
  TEXT     tx_highext      _gft4_3    _ls       _gwd4_1   .,		/*
  		*/label("High extension:") right
  EDIT     ed_highext      _gft4_4    @         _en7wd    .,		/*
  		*/label("High extension") option(highextension)
  GROUPBOX gb_dots         _lft       _vs4      _gwd4_1   _ht12h,	/*
  		*/label("Dot options")
  DEFINE holdy @y
  TEXT     tx_ndots        _igft      _ms       _txwd     .,		/*
  		*/label("How many:") right
  SPINNER  sp_ndots        _txsep     @         _spwd     .,		/*
  		*/label("How many:") min(0) max(1000) default(100) 	/*
  		*/option(ndots)
  TEXT     tx_msymb        _igft      _ls       _txwd     .,		/*
  		*/label("Symbol:") right
  COMBOBOX cb_msymb        _txsep     @         _txr4gi   .,		/*
  		*/label("Symbol") contents(_dclst_0) value(_dvlst_0)	/*
  		*/option(msymbol) dropdownlist
  TEXT     tx_msize        _lft4_1gi  _ls       _txwd     .,		/*
  		*/label("Size:") right
  COMBOBOX cb_msize        _txsep     @         _txr4gi   .,		/*
  		*/label("Size") contents(_dclst_1) value(_dvlst_1)	/*
  		*/option(msize) dropdownlist
  CHECKBOX ck_mcol         _lft4_1gi  _ls       _txwd     .,		/*
  		*/label("Color") 					/*
  		*/clickon(gaction gdl.cl_mcol.show)			/*
  		*/clickoff(gaction gdl.cl_mcol.hide)
  COLOR    cl_mcol         _txsep     @         _txr4gi  .,		/*
  		*/label("Color") default(255 0 0) option(mcolor)
  GROUPBOX gb_line         _gft4_2    holdy     _gwd4_1   _ht12h,	/*
  		*/label("Line options")
  CHECKBOX ck_lcol         _lft4_2gi  _ms       _txwd    .,		/*
  		*/label("Color") 					/*
  		*/clickon(gaction gdl.cl_lcol.show)			/*
  		*/clickoff(gaction gdl.cl_lcol.hide)
  COLOR    cl_lcol         _txsep     @         _txr4gi  .,		/*
  		*/label("Line color") option(lcolor) default(255 0 0)
  TEXT     tx_lpat         _lft4_2gi  _ls       _txwd    .,		/*
  		*/label("Pattern:") right
  COMBOBOX cb_lpat         _txsep     @         _txr4gi  .,		/*
  		*/label("Line pattern") contents(_dclst_4) 		/*
  		*/value(_dvlst_4) option(lpattern) dropdownlist
  TEXT     tx_lwid         _lft4_2gi  _ls       _txwd    .,		/*
  		*/label("Width:") right
  COMBOBOX cb_lwid         _txsep     @         _txr4gi  .,		/*
  		*/label("Line width") option(lwidth) 			/*
  		*/contents(_dclst_5) value(_dvlst_5) dropdownlist
  GROUPBOX gb_rect         _gft4_3    holdy     _gwd4_1  _ht12h,	/*
  		*/label("Rectangle options")
  TEXT     tx_rwid         _lft4_3gi  _ms       _txwd    .,		/*
  		*/label("Rect. width:") right
  EDIT     ed_rwid         _txsep     @         _txr4gi  .,		/*
  		*/label("Rectangle width") option(rwidth)
  CHECKBOX ck_rlcol        _lft4_3gi  _ls       _txwd    .,		/*
  		*/label("Color") 					/*
  		*/clickon(gaction gdl.cl_rlcol.show)			/*
  		*/clickoff(gaction gdl.cl_rlcol.hide)
  COLOR    cl_rlcol        _txsep     @         _txr4gi  .,		/*
  		*/label("Color") default(255 0 0) option(color)

END


LIST gdl_extend
BEGIN
	""
	extendline
	noextendline
END

LIST gdl_extend_change
BEGIN
	script gdl_extend_on
	script gdl_extend_on
	script gdl_extend_off
END

SCRIPT gdl_extend_on
BEGIN
	gdl.tx_lowext.enable
	gdl.ed_lowext.enable
	gdl.tx_highext.enable
	gdl.ed_highext.enable
END

SCRIPT gdl_extend_off
BEGIN
	gdl.tx_lowext.disable
	gdl.ed_lowext.disable
	gdl.tx_highext.disable
	gdl.ed_highext.disable
END
SCRIPT gdl_doton
BEGIN
	script gdl_lineoff
	script gdl_rectoff
	gdl.gb_dots.enable
	gdl.tx_ndots.enable
	gdl.sp_ndots.enable
	gdl.tx_msymb.enable
	gdl.cb_msymb.enable
	gdl.tx_msize.enable
	gdl.cb_msize.enable
	gdl.ck_mcol.enable
	gdl.cl_mcol.enable
END

SCRIPT gdl_dotoff
BEGIN
	gdl.gb_dots.disable
	gdl.tx_ndots.disable
	gdl.sp_ndots.disable
	gdl.tx_msymb.disable
	gdl.cb_msymb.disable
	gdl.tx_msize.disable
	gdl.cb_msize.disable
	gdl.ck_mcol.disable
	gdl.cl_mcol.disable
END


SCRIPT gdl_lineon
BEGIN
	script gdl_dotoff
	script gdl_rectoff
	gdl.gb_line.enable
	gdl.ck_lcol.enable
	gdl.cl_lcol.enable
	gdl.tx_lpat.enable
	gdl.cb_lpat.enable
	gdl.tx_lwid.enable
	gdl.cb_lwid.enable
END

SCRIPT gdl_lineoff
BEGIN
 	gdl.gb_line.disable
	gdl.ck_lcol.disable
	gdl.cl_lcol.disable
	gdl.tx_lpat.disable
	gdl.cb_lpat.disable
	gdl.tx_lwid.disable
	gdl.cb_lwid.disable
END

SCRIPT gdl_recton
BEGIN
	script gdl_dotoff
	script gdl_lineoff
	gdl.gb_rect.enable
	gdl.tx_rwid.enable
	gdl.ed_rwid.enable
	gdl.ck_rlcol.enable
	gdl.cl_rlcol.enable
END

SCRIPT gdl_rectoff
BEGIN
	gdl.gb_rect.disable
	gdl.tx_rwid.disable
	gdl.ed_rwid.disable
	gdl.ck_rlcol.disable
	gdl.cl_rlcol.disable
END

PROGRAM gdotline_dots_pr
BEGIN
	optionarg /hidedefault gdl.cb_msymb
	optionarg /hidedefault gdl.cb_msize
	if gdl.ck_mcol {
		optionarg /quoted gdl.cl_mcol
	}
END

PROGRAM gdotline_lines_pr
BEGIN
	if gdl.ck_lcol {
		optionarg /quoted gdl.cl_lcol
	}
	optionarg /hidedefault gdl.cb_lpat
	optionarg /hidedefault gdl.cb_lwid
END

PROGRAM gdotline_rec_pr
BEGIN
	if gdl.ck_rlcol {
		optionarg /quoted gdl.cl_rlcol
	}
END

PROGRAM gdotline_output
BEGIN
	optionarg /hidedefault gdl.ed_ogap
	optionarg /hidedefault gdl.en_linegap
	option radio (gdl rb_dot rb_line rb_rect)
	if gdl.rb_dot {
		optionarg /hidedefault gdl.sp_ndots
		if gdl.cb_msize | gdl.cb_msymb | gdl.ck_mcol {
			put "dots("
			put /program gdotline_dots_pr
			put ") "
		}
	}
	if gdl.rb_line {
		if gdl.ck_lcol | gdl.cb_lpat | gdl.cb_lwid {
			put "lines("
			put /program gdotline_lines_pr
			put ")"
		}
	}
	if gdl.rb_rect {
		optionarg /hidedefault gdl.ed_rwid
		if gdl.ck_rlcol {
			put " rectangles("
			put /program gdotline_rec_pr
			put ") "
		}
	}
	put gdl.cb_extend
	optionarg /hidedefault gdl.ed_lowext
	optionarg /hidedefault gdl.ed_highext
END