graph_copy.dlg

来自「是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到」· DLG 代码 · 共 78 行

/*
	graph copy

	VERSION 1.0.0  21dec2002
*/

VERSION 8.0

INCLUDE _std_small
INCLUDE header

HELP hlp1, view("help graph_copy")
RESET res1

DIALOG main, label("graph copy - Copy graph in memory") tabtitle("Main")
BEGIN
/*--+----1----+----2----+----3----+----4----+----5----+----6----+----7----+---*/
  RADIO    rb_curgr          _lft      _top      _iwd      ., first	/*
		*/ label("Copy current graph to new name")		/*
		*/ clickon(script curgr_on)
  EDIT     ed_newgr1          _indent2 _ms       _vnwd     .,		/*
		*/ label("New graph name")

  RADIO    rb_existgr        _lft      _ls       _iwd      ., last	/*
		*/ label("Copy existing graph to new graph name")	/*
		*/ clickon(script existgr_on)
  TEXT     tx_exgr           _indent2  _ss       _cwd1     .,		/*
		*/ label("Existing graph name:")
  DEFINE   holdy @y
  COMBOBOX cb_exgr           @         _ss       _vnwd     .,		/*
		*/ dropdown						/*
		*/ contents(graphs)					/*
		*/ label("Existing graph name")
  TEXT     tx_newgr2         _lft2     holdy     _cwd1     .,		/*
		*/ label("New graph name:") 
  EDIT     ed_newgr2         @         _ss       _vnwd     .,		/*
		*/ label("New graph name 2")
  CHECKBOX ck_replace        _lft      _xls      _iwd      .,		/*
  	*/ label("Replace new graph name if it already exists in memory")/*
  		*/ option(replace) nomem
END

SCRIPT curgr_on
BEGIN
	main.ed_newgr1.enable
	main.tx_exgr.disable
	main.cb_exgr.disable
	main.tx_newgr2.disable
	main.ed_newgr2.disable
END

SCRIPT existgr_on
BEGIN
	main.tx_exgr.enable
	main.cb_exgr.enable
	main.tx_newgr2.enable
	main.ed_newgr2.enable
	main.ed_newgr1.disable
END

PROGRAM command
BEGIN
	put "graph copy "
	if main.rb_curgr {
		require main.ed_newgr1
		put main.ed_newgr1
	}
	if main.rb_existgr {
		require main.cb_exgr
		require main.ed_newgr2
		put main.cb_exgr
		put " "main.ed_newgr2
	}
	beginoptions
		option main.ck_replace
	endoptions
END