gr_use.ado

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

*! version 1.0.3  25jan2005
program define gr_use
	version 8

	syntax anything(name=filenm id=file) [ , * ]
	local 0 `", `options'"'

	capture gs_fileinfo `filenm' , suffix

	if "`r(ft)'" == "old"  {			// old format graph
		syntax [, FAKE_OPT_FOR_BETTER_MSG ]
		graph7 using `filenm'
		exit
	}

	if "`r(ft)'" == "asis"  {			// asis graph
		syntax [, FAKE_OPT_FOR_BETTER_MSG ]
		_asis use `filenm'
		exit
	}

	if "`r(ft)'" != "live"  {
		gs_fileinfo `filenm' , suffix
		exit 198
	}

							// live graph

	syntax [ , Name(string) SCHeme(passthru) REFSCHeme noSTYLEs noDRAW ]

	local 0 `name'
	syntax [anything(name=name)] [ , replace ]
	if "`name'" == "" {
		local replace replace
	}

	gr_setscheme , `scheme' `refscheme'
	gr_current name : `name' , newgraph `replace'

	capture noisily {
		.__Map = .null.new			// global 

		/* rebuild the object */
		gr_read `name' `"`filenm'"' 0`="`styles'"!=""'		///
			 0`= "`scheme'"=="" '

	} 
	local rc = _rc

	capture _cls free __Map

	if `rc' {
		exit `rc'
	}

	if "`draw'" == "" {
		gr_draw `name'
	}

	_gs_addgrname `name'				// register graph name

end