graph_describe.dlg

来自「是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到」· DLG 代码 · 共 71 行

/*
	graph describe

	VERSION 1.0.0  21dec2002
*/

VERSION 8.0

INCLUDE _std_small
INCLUDE header
HELP hlp1, view("help graph_describe")
RESET res1

DIALOG main, label("graph describe - Describe graph") 			/*
		*/ tabtitle("Main")
BEGIN
  RADIO    rb_curgr          _lft      _top      _iwd      ., first	/*
		*/ label("Describe graph currently in Graph window")	/*
		*/ clickon("script currentgraph")

  RADIO    rb_memgr          _lft      _xxls     _iwd      .,		/*
		*/ label("Describe graph in memory, if any")		/*
		*/ clickon("script memorygraph")
  COMBOBOX cb_memgr          _indent2  _ss       _ibwd     .,		/*
		*/ label("Describe graph in memory")			/*
		*/ dropdown						/*
		*/ contents(graphs)

  RADIO    rb_diskgr         _lft      _xxls     _iwd      ., last	/*
		*/ label("Describe graph on disk")			/*
		*/ clickon("script diskgraph")
  FILE     fi_diskgr         _indent2  _ss       _ibwd     .,		/*
		*/ label("Browse...")					/*
		*/ filter("Stata Graphs (*.gph)|*.gph|All Files (*.*)|*.*")/*
		*/ defext(gph)						/*
		*/ error("Describe graph on disk")
END

SCRIPT currentgraph
BEGIN
	main.cb_memgr.disable
	main.fi_diskgr.disable
END

SCRIPT memorygraph
BEGIN
	main.cb_memgr.enable
	main.fi_diskgr.disable
END

SCRIPT diskgraph
BEGIN
	main.fi_diskgr.enable
	main.cb_memgr.disable
END

PROGRAM command
BEGIN
	put "graph describe "
	if main.rb_memgr {
		require main.cb_memgr
		put main.cb_memgr
	}
	if main.rb_diskgr {
		require main.fi_diskgr
		put `"""'
		put main.fi_diskgr
		put `"""'
	}
END