gtitle_98s.idlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  gtitle_98s.idlg Include for graphics titles 
  **Special version for Windows95/98
  
*!  VERSION 1.0.2  20mar2005
  
  This idlg assumes you are using _graph.idlg include and _std_graph.idlg
  include to set the proper lengths, widths and heights.
*/

DIALOG gtitle, label() tabtitle("Title")
BEGIN
  
  /* LEFT SIDE-- Title */
  GROUPBOX gb_title    _lft        _top      _gwd1       _ht12,		/*
		*/ label("Title ")   
  EDIT     ed_title    _lft1g      _ss       _cwd1gb     .,		/*
		*/ label("Title") 					/*
		*/ option(title)
  /* LEFT SIDE-- Title col(1) */
  TEXT     tx_size     _igft       _ms       _txwd       .,		/*
		*/ label("Size:")					/*
		*/ right
  DEFINE   y @y         
  COMBOBOX cb_size     _txsep      @         _txr2b4g    .,		/*
		*/ dropdownlist						/*
		*/ contents(textsizes) 					/*
		*/ option(size)
  TEXT     tx_posit    _igft       _ms       _txwd       .,		/*
		*/ label("Position:")					/*
		*/ right    
  COMBOBOX cb_posit    _txsep      @         _txr2b4g    .,		/*
		*/ dropdownlist						/*
		*/ contents(clockpos) 					/*
		*/ option(position)
  CHECKBOX ck_ring     @           _ms       _txr2gi     .,		/*
		*/ label("Inside plot region")				/*
		*/ clickon(program gtitle_ring_check)			/*
		*/ clickoff(program gtitle_ring_check)			/*
		*/ option(ring(0))
  CHECKBOX ck_span     @           _ms       _txr2gi     .,		/*
		*/ label("Span width of graph")				/*
		*/ clickon(program gtitle_span_check)			/*
		*/ clickoff(program gtitle_span_check)			/*
		*/ option(span)
  
  /* LEFT SIDE-- Caption */
  GROUPBOX gb_stitle   _gft2       _top      _gwd1       _ht12,		/*
		*/ label("Caption ")   
  EDIT     ed_stitle   _igft2      _ss       _cwd1gb     .,		/*
		*/ label("Caption") 					/*
		*/ option(caption)
  /* LEFT SIDE-- Sub Title col(1) */
  TEXT     tx_ssize    _igft2      _ms       _txwd       .,		/*
		*/ label("Size:")					/*
		*/ right
  DEFINE   y @y         
  COMBOBOX cb_ssize    _txsep      @         _txr2b4g    .,		/*
		*/ dropdownlist						/*
		*/ contents(textsizes) 					/*
		*/ option(size)
  TEXT     tx_sposit   _igft2      _ms       _txwd       .,		/*
		*/ label("Position:")					/*
		*/ right    
  COMBOBOX cb_sposit   _txsep      @         _txr2b4g    .,		/*
		*/ dropdownlist						/*
		*/ contents(clockpos) 					/*
		*/ option(position)
  CHECKBOX ck_sring    @           _ms       _txr2gi     .,		/*
		*/ label("Inside plot region")				/*
		*/ clickon(program gtitle_sring_check)			/*
		*/ clickoff(program gtitle_sring_check)			/*
		*/ option(ring(0))
  CHECKBOX ck_sspan    @           _ms       _txr2gi     .,		/*
		*/ label("Span width of graph")				/*
		*/ clickon(program gtitle_sspan_check)			/*
		*/ clickoff(program gtitle_sspan_check)			/*
		*/ option(span)
  
END

PROGRAM gtitle_ring_check
BEGIN
	if !H(gtitle.ck_ring) {
		if gtitle.ck_ring {
			call script gtitle_ring_on
		}
		if !gtitle.ck_ring {
			call program gtitle_ring_off
		}
	}
END

PROGRAM gtitle_span_check
BEGIN
	if !H(gtitle.ck_span) {
		if gtitle.ck_span {
			call gaction gtitle.ck_ring.disable
		}
		if !gtitle.ck_span {
			call gaction gtitle.ck_ring.enable
		}
	}
END

PROGRAM gtitle_sring_check
BEGIN
	if !H(gtitle.ck_sring) {
		if gtitle.ck_sring {
			call script gtitle_sring_on
		}
		if !gtitle.ck_sring {
			call program gtitle_sring_off
		}
	}
END

PROGRAM gtitle_sspan_check
BEGIN
	if !H(gtitle.ck_sspan) {
		if gtitle.ck_sspan {
			call gaction gtitle.ck_sring.disable
		}
		if !gtitle.ck_sspan {
			call gaction gtitle.ck_sring.enable
		}
	}
END

SCRIPT gtitle_ring_on
BEGIN
	gtitle.ck_span.disable
END

PROGRAM gtitle_ring_off
BEGIN
	call gaction gtitle.ck_span.enable
END

SCRIPT gtitle_sring_on
BEGIN
	gtitle.ck_sspan.disable
END

PROGRAM gtitle_sring_off
BEGIN
	call gaction gtitle.ck_sspan.enable
END



/* Script to enable this tab */
SCRIPT gtitle_enable
BEGIN
	program gtitle_enable_pr
END

PROGRAM gtitle_enable_pr
BEGIN
	call gaction gtitle.gb_title.enable
	call gaction gtitle.ed_title.enable
	call gaction gtitle.tx_size.enable
	call gaction gtitle.cb_size.enable
	call gaction gtitle.tx_posit.enable
	call gaction gtitle.cb_posit.enable
	if !gtitle.ck_span {
		call gaction gtitle.ck_ring.enable
	}
	if !gtitle.ck_ring {
		call gaction gtitle.ck_span.enable
	}

	call gaction gtitle.gb_stitle.enable
	call gaction gtitle.ed_stitle.enable
	call gaction gtitle.tx_ssize.enable
	call gaction gtitle.cb_ssize.enable
	call gaction gtitle.tx_sposit.enable
	call gaction gtitle.cb_sposit.enable
	if !gtitle.ck_sspan {
		call gaction gtitle.ck_sring.enable
	}
	if !gtitle.ck_sring {
		call gaction gtitle.ck_sspan.enable
	}

END

/* Script to disable this tab */
SCRIPT gtitle_disable
BEGIN
	gtitle.gb_title.disable
	gtitle.ed_title.disable
	gtitle.tx_size.disable
	gtitle.cb_size.disable
	gtitle.tx_posit.disable
	gtitle.cb_posit.disable
	gtitle.ck_ring.disable
	gtitle.ck_span.disable

	gtitle.gb_stitle.disable
	gtitle.ed_stitle.disable
	gtitle.tx_ssize.disable
	gtitle.cb_ssize.disable
	gtitle.tx_sposit.disable
	gtitle.cb_sposit.disable
	gtitle.ck_sring.disable
	gtitle.ck_sspan.disable
END

PROGRAM gtitle_title_pr
BEGIN
/* Title */
    if !H(gtitle.ed_title) & 					///
        ( gtitle.ed_title | gtitle.cb_size | gtitle.cb_posit 	///
        | gtitle.ck_ring | gtitle.ck_span ) {
	put "title(" gtitle.ed_title
	put /program gtitle_title_opt_pr 
	put ") "
    }
END

PROGRAM gtitle_title_opt_pr
BEGIN
	beginoptions
		optionarg /hidedefault gtitle.cb_size         
		optionarg /hidedefault gtitle.cb_posit
		option gtitle.ck_ring
		option gtitle.ck_span
	endoptions 
END
   
PROGRAM gtitle_caption_pr
BEGIN

/* Sub-title */ 
   if !H(gtitle.ed_stitle) & 					///
        ( gtitle.ed_stitle | gtitle.cb_ssize | gtitle.cb_sposit ///
        | gtitle.ck_sring | gtitle.ck_sspan ) {
	put "caption(" gtitle.ed_stitle
	put /program gtitle_caption_opt_pr
	put ") "
    }
END

PROGRAM gtitle_caption_opt_pr
BEGIN
	beginoptions
		optionarg /hidedefault gtitle.cb_ssize         
		optionarg /hidedefault gtitle.cb_sposit
		option gtitle.ck_sring
		option gtitle.ck_sspan
	endoptions 
END

PROGRAM gtitle_output
BEGIN
	put " "  /program gtitle_title_pr
	put " "  /program gtitle_caption_pr
END