gnbreg.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  gnbreg

*! VERSION 1.1.2  22mar2005

  keyword:  eclass

*/

VERSION 9.0

INCLUDE _std_large
INCLUDE _ht330
INCLUDE header
HELP hlp1, view("help gnbreg")
RESET res1

DIALOG main, label("gnbreg - Generalized negative binomial regression")	/*
		*/ tabtitle("Model")
BEGIN
  INCLUDE _dviv

  CHECKBOX ck_nocons @         _ms       @         .,			/*
		*/ label("Suppress constant term")			/*
		*/ option("noconstant")					/*
		*/

  GROUPBOX gb_opt    _lft      _ls       _iwd      _ht15,		/*
		*/ label("Options")					/*
		*/

  TEXT     tx_lnalph _ilft     _ss       _inwd     .,			/*
		*/ label("Dispersion model variables:")			/*
		*/
  VARLIST  vl_lnalph @         _ss       @         .,			/*
		*/ label("Dispersion model variables")			/*
		*/ allowcat						/*
		*/ option("lnalpha")					/*
		*/

  RADIO    rb_expose _ilft     _ls       _cwd3_2   .,			/*
		*/ label("Exposure variable:")				/*
		*/ first						/*
		*/ clickon("script expose")				/*
		*/
  RADIO    rb_offset _lft3_2   @         @         .,			/*
		*/ label("Offset variable:")				/*
		*/ last							/*
		*/ clickon("script offset")				/*
		*/

  VARNAME  vn_expose _ilft     _ss       @         .,			/*
		*/ label("Exposure variable")				/*
		*/ option("exposure")					/*
		*/

  VARNAME  vn_offset _lft3_2   @         @         .,			/*
		*/ label("Offset variable")				/*
		*/ option("offset")					/*
		*/
  DEFINE _x _ilft
  DEFINE _cx _ibwd
  DEFINE _y _ls
  INCLUDE _constraints
END

SCRIPT expose
BEGIN
  main.vn_expose.enable
  main.vn_offset.disable
END

SCRIPT offset
BEGIN
  main.vn_expose.disable
  main.vn_offset.enable
END

INCLUDE ifin
INCLUDE weights_fpi
INCLUDE se

SCRIPT PREINIT
BEGIN
	script se_createAsJknifeBstrapML
END

DIALOG rpt, tabtitle("Reporting")
BEGIN
  DEFINE _x _lft
  DEFINE _cx _spr
  DEFINE _y _top
  INCLUDE _sp_level

  RADIO    rb_default _lft     _ls       _cwd1     .,			/*
  		*/ label("Report coefficients (default)") first
  RADIO    rb_irr     @        _ss       @         .,			/*
  		*/ label("Report incidence-rate ratios")		/*
  		*/ option(irr) last
END

INCLUDE max_ml

PROGRAM command
BEGIN
	allowxi
	put "gnbreg "
	varlist main.vn_dv [main.vl_iv]
	if !main.vl_iv & main.ck_nocons {
	  stopbox stop `""Suppress constant term" is selected without independent variables."'
	}
	INCLUDE _weights_pr
	INCLUDE _ifin_pr
	beginoptions
		option main.ck_nocons
		optionarg main.vl_lnalph
		optionarg main.vn_expose
		optionarg main.vn_offset
		INCLUDE _constraints_main_pr
		put " " /program se_output
		optionarg /hidedefault rpt.sp_level
		option rpt.rb_irr
		put " " /program max_output
	endoptions
END