graph_matrix_98s.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  graph matrix Version 98s

*!  VERSION 1.1.2  01apr2005

*/
VERSION 9.0

INCLUDE graph_header
INCLUDE header
HELP hlp1, view("help graph_matrix")
RESET res1

DIALOG main, label("graph matrix - Draw scatterplot matrices") /*
		*/ tabtitle("Main")
BEGIN
  /*--+----1----+----2----+----3----+----4----+----5----+----6----+----7----+*/
  GROUPBOX gb_reqd         _lft        _top       _iwd         _ht2,	/*
  		*/ label("Required")
  TEXT     tx_var          _ilft       _ss        _txwd        .,	/*
  		*/label("Variables:")
  VARLIST  vl_var          _txsep      @          _txrb        .,	/*
  		*/label("Variables")
  TEXT     tx_if           _gft2       _xls       _ifwd        .,	/*
  		*/ label("if:")
  EXP      ex_if           _indent2    @          _edifwd1g    .,	/*
  		*/ label("Create...") error(If)
  DEFINE holdy @y
  CHECKBOX ck_half         _lft        @          _gwd4_1      .,	/*
  		*/ label("Lower triangular half only") option(half)
  TEXT     tx_scale        _lft4_2g    holdy      _txlwd       .,	/*
  		*/ label("Scale text:")  right
  EDIT     ed_scale        _txlsep     @          _en7wd       .,	/*
  		*/ label("Scale text") default(1) option(scale)
  GROUPBOX gb_marker       _lft        _ls        _cwd4_g      _ht9h,	/*
  		*/label("Markers")
  DEFINE holdy @y
  TEXT     tx_msym         _lft4_1gi   _ss        _txwd        .,	/*
  		*/label("Symbol: ") right
  COMBOBOX cb_msym         _txsep      @          _txr4gi      .,	/*
  		*/option(msymbol) dropdownlist contents(symbols)
  TEXT     tx_msize        _lft4_1gi   _ms        _txwd        .,	/*
  		*/label("Size:") right
  COMBOBOX cb_msize        _txsep      @          _txr4gi      .,	/*
  		*/option(msize) contents(symbolsizes) dropdownlist
  CHECKBOX ck_mcol         _lft4_1gi   _ms        _txwd        .,	/*
  		*/label("Color") onclickon(gaction main.cl_mcol.show)	/*
  		*/onclickoff(gaction main.cl_mcol.hide)
  COLOR    cl_mcol         _txsep      @          _txr4gi      .,	/*
  		*/option(mcolor)
  TEXT     tx_jit          _lft4_1gi   _ms        _txwd        .,	/*
  		*/ label("Jitter:") right
  EDIT     ed_jit          _txsep      @          _en7wd       .,	/*
  		*/ label("Jitter") option(jitter) default("0")
  BUTTON   bu_jit          _en7sep     @          _btwd        .,	/*
  		*/ label(?) onpush("view help relativesize##|_new")
  CHECKBOX ck_mlab         _lft4_2g    holdy      _cwd4_g      _ht2h,	/*
  		*/label("Marker labels") groupbox 			/*
  		*/clickon(script main_mlab_on) clickoff(script main_mlab_off)
  TEXT     tx_mlab         _lft4_2gi   _ms        _txwd        .,	/*
  		*/label("Variable: ") right
  VARLIST  vl_mlab         _txsep      @          _txr4gi      .,	/*
  		*/label("Marker labels variable") option(mlabel)
  /* RIGHT SIDE-- diagonal labels*/
  GROUPBOX gb_dtitle       _lft2g      holdy      _gwd1        _ht16h,	/*
		*/label("Diagonal labels")
  EDIT     ed_dtitle       _igft2      _ss        331         .,	/*
		*/label("Diagonal labels") option(diagonal)
  BUTTON   bu_dtitle       +334        @          _btwd       .,	/*
  		*/ label("?") onpush(view help gdiagonal##|_new)

  /* RIGHT SIDE-- Diag labels col(1)*/
  TEXT     tx_dsize        _igft2      _ms        _txwd       .,	/*
		*/ label("Size:")					/*
		*/ right
  DEFINE   y @y
  COMBOBOX cb_dsize        _txsep      @          _txr2b4g    .,	/*
		*/ dropdownlist option(size) contents(textsizes)
  CHECKBOX ck_dclr         _igft2      _ls        _txwd       .,	/*
		*/ label("Color:")					/*
		*/ onclickon(gaction main.cl_dclr.show)			/*
		*/ onclickoff(gaction main.cl_dclr.hide)
  COLOR    cl_dclr         _txsep      @          _txr2b4g    .,	/*
		*/option(color)
  DEFINE   y2 @y

  /* RIGHT SIDE-- Diagonal labels upper col(2)*/
  TEXT     tx_dorient      _gft4_4     y          _txwd       .,	/*
		*/ label("Orientation:")				/*
		*/ right
  COMBOBOX cb_dorient      _txsep      @          _txr2b4g    .,	/*
		*/ dropdownlist						/*
		*/ label("Orientation")	option(orientation)		/*
		*/ contents(orientation) value(orientation_values)

  /* RIGHT SIDE-- Diagonal labels lower*/
  CHECKBOX ck_dbox         _igft2      _xxxls     _cwd1gb     _ht5,	/*
		*/ groupbox						/*
		*/ clickon(program main_dbox_on)			/*
		*/ clickoff(script main_dbox_off)			/*
		*/ label ("Draw box around label") option(box)
  /* RIGHT SIDE-- Diagonal labels lower col(1)*/
  CHECKBOX ck_dbclr        _iigft2     _ms        _txswd      .,	/*
		*/ label("Color:")					/*
		*/ onclickon(gaction main.cl_dbclr.show)		/*
		*/ onclickoff(gaction main.cl_dbclr.hide)
  COLOR    cl_dbclr        _txssep     @          _txr2b4g    .,	/*
		*/ option(bcolor)
  DEFINE holdx @x
  DEFINE y3 @y
  CHECKBOX ck_dexpand      _iigft2     _ms        _cwd2b4_g   .,	/*
		*/ label("Ignore text size") option(bexpand)
  TEXT     tx_dbmargin     _igft4_4    y3         _txswd      .,	/*
		*/ label("Margin:")					/*
		*/ right
  COMBOBOX cb_dbmargin     _txssep     @          _txr2b4g    .,	/*
		*/ dropdown option(bmargin) contents(margin)
  CHECKBOX ck_hideme       _lft        _ms        0           0, label("")/*
  		*/clickon(script main_gbyaction) 			/*
  		*/clickoff(script main_gbyaction)
END

INCLUDE gmxaxis_98s
INCLUDE gmyaxis_98s
INCLUDE gtitle_98s
INCLUDE gregion_98s
INCLUDE gby_98s

SCRIPT main_gbyaction
BEGIN
	main.ck_hideme.hide
	script gby_gmatrix_hide
END

SCRIPT main_mlab_on
BEGIN
	main.tx_mlab.enable
	main.vl_mlab.enable
END

SCRIPT main_mlab_off
BEGIN
	main.tx_mlab.disable
	main.vl_mlab.disable
END

LIST main_cl_dclr_sel
BEGIN
	main.cl_dclr.hide
	main.cl_dclr.show
	main.cl_dclr.hide
END

PROGRAM main_dbox_on
BEGIN
	call gaction main.ck_dbclr.enable
	call gaction main.cl_dbclr.enable
	call gaction main.tx_dbmargin.enable
	call gaction main.cb_dbmargin.enable
	call gaction main.ck_dexpand.enable
END

SCRIPT main_dbox_off
BEGIN
	main.ck_dbclr.disable
	main.cl_dbclr.disable
	main.tx_dbmargin.disable
	main.cb_dbmargin.disable
	main.ck_dexpand.disable
END

PROGRAM main_diaglab_opt
BEGIN
	beginoptions
		optionarg /hidedefault main.cb_dsize
		if !H(main.cl_dclr) {
			optionarg /quoted main.cl_dclr
		}
      		optionarg /hidedefault main.cb_dorient
      		option main.ck_dbox
		if main.ck_dbox {
        		if !H(main.cl_dbclr) {
				optionarg /quoted main.cl_dbclr
			}
         		optionarg /hidedefault main.cb_dbmargin
	 		option main.ck_dexpand
		}
	endoptions
END

PROGRAM main_diaglab_pr
BEGIN
/* Diagonal labels */
   	if main.ed_dtitle | main.cb_dsize | !H(main.cl_dclr) |/*
           */ main.cb_dorient | 		 	/*
           */ main.ck_dbox {
      		put "diagonal(" main.ed_dtitle
		put /program main_diaglab_opt
	   	put ")"
	}
END


PROGRAM command
BEGIN
	put "graph matrix "
	varlist main.vl_var
	ifexp main.ex_if
	beginoptions
		put /program main_diaglab_pr
		option main.ck_half
		optionarg /hidedefault main.ed_scale
		optionarg /hidedefault main.ed_jit
		optionarg main.cb_msym
		optionarg main.cb_msize
		if !H(main.cl_mcol) {
			hoptionarg /quoted main.cl_mcol
		}
		if main.ck_mlab {
			require main.vl_mlab
			optionarg main.vl_mlab
		}
		put " " /program gmxaxis_output
		put " " /program gmyaxis_output
		put " " /program gtitle_output
		put " " /program gregion_output
		put " " /program gby_output
	endoptions
END