varsoc_pre.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  varsoc_pre.dlg -- varsoc (pre-estimation syntax)

  VERSION 1.0.0  21dec2002
*/
VERSION 8.0

INCLUDE _std_large
INCLUDE _ht290
INCLUDE header
HELP hlp1, view("help varsoc")
RESET res1

DIALOG main, ///
  label("varsoc - Obtain lag-order selection statistics (pre-estimation)") ///
	tabtitle("Main")
BEGIN
  DEFINE _x _xsetbu
  DEFINE _y _top
  INCLUDE _bu_tsset
  TEXT     tx_depv         _lft      _topph     _comb3_2 .,		///
		label("Dependent variables:")
  VARLIST  vl_depv         @         _ss        _iwd     .,		///
		label("Dependent variables")

  SPINNER  sp_maxlag       _lft      _ls        _spwd    .,		///
		label("Maximum lag order") option(maxlag)		///
		min(2) max(1000) default(4)
  TEXT     tx_maxlag       _spsep    @          _spr     .,		///
		label("Maximum lag order")

  CHECKBOX ck_exog         _lft      _ls        _iwd     .,		///
		label("Exogenous variables:")				///
		clickon(script exog_on)					///
		clickoff(script exog_off)
  VARLIST  vl_exog         _indent2  _ss        _inwd    .,		///
		label("Exogenous variables:") option(exog)

  TEXT     tx_constraints  @         _ls        @        .,		///
		label("Constraints on exogenous variables:")
  COMBOBOX cb_constraints  @         _ss        @        .,		///
		label("Constraints on exogenous variables")		///
		option(constraints) contents(constraints)		///
		dropdown append

  CHECKBOX ck_noconstant   _lft      _ls        _iwd     .,		///
		option(noconstant) label("Suppress constant terms")

  CHECKBOX ck_lutstats     @         _ls        _iwd     .,		///
		option(lutstats)					///
		label("Report Lutkepohl version of information criteria")

  SPINNER  sp_separator    _lft2     _ls        _spwd    .,		///
		label("Separator every N lines")			///
		min(0) max(1000000000) default(0) option(separator)
  TEXT     tx_separator    _spsep    @          _spr2    .,		///
		label("Separator every N lines")

  DEFINE _x _lft
  DEFINE _y @
  DEFINE _cx _spr2
  INCLUDE _sp_level
END


INCLUDE byifin


SCRIPT exog_on
BEGIN
	main.vl_exog.enable
	main.tx_constraints.enable
	main.cb_constraints.enable
END

SCRIPT exog_off
BEGIN
	main.vl_exog.disable
	main.tx_constraints.disable
	main.cb_constraints.disable
END


PROGRAM command
BEGIN
	INCLUDE _by_pr
	put "varsoc "
	varlist main.vl_depv
	INCLUDE _ifin_pr
	beginoptions
		optionarg main.sp_maxlag
		if main.ck_exog {
			require main.vl_exog
			optionarg main.vl_exog
			optionarg main.cb_constraints
		}
		option main.ck_noconstant
		option main.ck_lutstats
		optionarg /hidedefault main.sp_separator
		INCLUDE _level_main_pr
	endoptions
END