bylegend_g.class

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

//                               bylegend_g
//
//  by graph legend.  Really just a holder with a draw flag.


*! version 1.0.0  15sep2002

version 8


class {
    instance:
    	draw_view = .influenced_yesno.new			// over-ride

} , inherit(legend_g)


// ---------------------------------------------------------------------------
program new
	args src draw

	if ("`src'" == "") exit

	if ! 0`.`src'.isofclass legend_g' {
		di as error "bylegend_g.new, source is not a legend"
		exit 198
	}

	.draw_view.setstyle, style(`draw')

						// turn us into our source
						// legend by reference.
	foreach attrib_arr in instancemv dynamicmv {
		forvalues i = 1/0`.`src'.`attrib_arr'.arrnels' {
			_cls nameof `src' `attrib_arr'[`i']
			local attrib `r(name)'

			if "`attrib'" == "style" { 
				continue 
			}
			if "`attrib'" == "draw_view" { 
				continue 
			}

			if "`.`attrib'.isa'" != "" {
				.`attrib'.ref     = .`src'.`attrib'.ref
			}
			else	.Declare `attrib' = .`src'.`attrib'.ref
		}
	}

							// handle the style
	if "`.`src'.style.stylename'" == "" {
		.style.ref = .`src'.style.ref
	}
	else	.style.setstyle,  style(`.`src'.style.stylename')

end