bprobit.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  bprobit

*! VERSION 1.1.1  15mar2005

  keyword:  eclass

*/

VERSION 9.0

INCLUDE _std_large
INCLUDE header
HELP hlp1, view("help bprobit")
RESET res1

DIALOG main, label("bprobit - Probit regression for grouped data")	/*
		*/ tabtitle("Model")
BEGIN
  TEXT     tx_pos    _lft      _top      _cwd1     .,			/*
		*/ label("Outcome variable:")				/*
		*/
  VARNAME  vn_pos    @         _ss       _vnwd     .,			/*
		*/ label("Outcome variable")				/*
		*/
  TEXT     tx_pop    _vlx      _top      _cwd1     .,			/*
		*/ label("Population variable:")			/*
		*/
  VARNAME  vn_pop    @         _ss       _vnwd     .,			/*
		*/ label("Population variable")				/*
		*/
  TEXT     tx_iv     _lft      _ls       _iwd      .,			/*
		*/ label("Independent variables:")			/*
		*/
  VARLIST  vl_iv     @         _ss       @         .,			/*
		*/ label("Independent variables")			/*
		*/ allowcat						/*
		*/
  CHECKBOX ck_nocons @         _ms       _cwd1     .,			/*
		*/ label("Suppress constant term")			/*
		*/ option("noconstant")					/*
		*/
  CHECKBOX ck_asis   _lft      _ms       _cwd1     .,			/*
		*/ label("Retain perfect predictor variables")		/*
		*/ option("asis")					/*
		*/
  TEXT     tx_offset @         _ls       _cwd2     .,			/*
		*/ label("Offset variable: (optional)")			/*
		*/
  VARNAME  vn_offset @         _ss       _vnwd     .,			/*
		*/ label("Offset variable")				/*
		*/ option("offset")					/*
		*/

END

INCLUDE byifin
INCLUDE se

SCRIPT PREINIT
BEGIN
	script se_createAsInternalML
END

DIALOG rpt, tabtitle("Reporting")
BEGIN
  DEFINE _x _lft
  DEFINE _cx _spr
  DEFINE _y 20
  INCLUDE _sp_level
END

INCLUDE max_internal

SCRIPT POSTINIT
BEGIN
	script max_setDefaultNoLog
END

PROGRAM command
BEGIN
	allowxi
	INCLUDE _by_pr
	put "bprobit "
	require main.vn_pos
	put main.vn_pos " "
	require main.vn_pop
	put main.vn_pop " "
	put main.vl_iv " "
	if !main.vl_iv & main.ck_nocons {
	  stopbox stop `""Suppress constant term" is selected without independent variables."'
	}
	INCLUDE _ifin_pr
	beginoptions
		optionarg main.vn_offset
		option main.ck_nocons
		option main.ck_asis
		put " " /program se_output
		optionarg /hidedefault rpt.sp_level
		put " " /program max_output
	endoptions
END