biprobit_notsu.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  biprobit

*! VERSION 1.1.1  21feb2005

  keyword:  eclass

*/

VERSION 9.0

INCLUDE _std_large
INCLUDE _ht330
INCLUDE header
HELP hlp1, view("help biprobit")
RESET res1

DIALOG main, label("biprobit - Bivariate probit regression")		/*
		*/ tabtitle("Model")
BEGIN
  TEXT     tx_dv1    _lft      _top      _vnwd      .,			/*
		*/ label("Dependent variable 1:")			/*
		*/
  VARNAME  vn_dv1    @         _ss       _vnwd     .,			/*
		*/ label("Dependent variable 1")			/*
		*/

  TEXT     tx_dv2    _vlx      _top      _vnwd      .,			/*
		*/ label("Dependent variable 2:")			/*
		*/
  VARNAME  vn_dv2    @         _ss       _vnwd     .,			/*
		*/ label("Dependent variable 2")			/*
		*/

  TEXT     tx_iv     _lft      _ls       _iwd      .,			/*
		*/ label("Independent variables:")			/*
		*/
  VARLIST  vl_iv     @         _ss       @         .,			/*
		*/ label("Independent variables")			/*
		*/ allowcat						/*
		*/
  CHECKBOX ck_nocons @         _ms       @         .,			/*
		*/ label("Suppress constant term")			/*
		*/ option("noconstant")					/*
		*/

  GROUPBOX gb_output _lft      _ls       _iwd      _ht13,		/*
		*/ label("Options")					/*
		*/
  CHECKBOX ck_part   _ilft     _ms       _cwd2     .,			/*
		*/ label("Fit partial observability model")		/*
		*/ option("partial")					/*
		*/
  TEXT     tx_off1   _ilft     _ms       _cwd2     .,			/*
		*/ label("Eq. 1 offset variable:")			/*
		*/
DEFINE y @y
  VARNAME  vn_off1   @         _ss       _vnwd     .,			/*
		*/ label("Eq. 1 offset variable")			/*
		*/ option("offset1")					/*
		*/
  TEXT     tx_off2   _vlx      y         _cwd2     .,			/*
		*/ label("Eq. 2 offset variable:")			/*
		*/
  VARNAME  vn_off2   @         _ss       _vnwd     .,			/*
		*/ label("Eq. 2 offset variable")			/*
		*/ option("offset2")					/*
		*/
  DEFINE _x _ilft
  DEFINE _cx _ibwd
  DEFINE _y _ls
  INCLUDE _constraints
END

INCLUDE byifin
INCLUDE weights_fpi
INCLUDE se

SCRIPT PREINIT
BEGIN
	script se_createAsJknifeBstrapML
END

DIALOG rpt, tabtitle("Reporting")
BEGIN
  DEFINE _x _lft
  DEFINE _cx _spr
  DEFINE _y _top
  INCLUDE _sp_level

  GROUPBOX gb_tests  _lft      _xls     _iwd      _ht2,			/*
  		*/ label("Additional test statistics")
  CHECKBOX ck_noskip _ilft     _ss      _cwd1     .,			/*
		*/ label("Perform likelihood-ratio test")		/*
		*/ option("noskip")					/*
		*/

END

INCLUDE max_ml

PROGRAM command
BEGIN
	allowxi
	INCLUDE _by_pr
	put "biprobit "
	varlist main.vn_dv1 main.vn_dv2 [main.vl_iv]
	if !main.vl_iv & main.ck_nocons {
	  stopbox stop `""Suppress constant term" is selected without independent variables."'
	}
	INCLUDE _weights_pr
	INCLUDE _ifin_pr
	beginoptions
		INCLUDE _constraints_main_pr
		option main.ck_nocons
		option main.ck_part
		optionarg main.vn_off1
		optionarg main.vn_off2
		put " " /program se_output
		optionarg /hidedefault rpt.sp_level
		option rpt.ck_noskip
		put " " /program max_output
	endoptions
END