blogit.ado

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

*! version 3.3.3  31mar2005
program define blogit, eclass byable(onecall) properties(or)
	if _by() {
		local BY `"by `_byvars'`_byrc0':"'
	}
	`BY' _vce_parserun blogit, jkopts(nocount) : `0'
	if "`s(exit)'" != "" {
		exit
	}

	version 6, missing
	if replay() {
		if "`e(cmd)'"!="blogit" { error 301 }
		if _by() { error 190 }
		syntax [, Level(cilevel) or ]
		loc dep "`e(depvar)'"
		est local depvar "_outcome"
		logit, level(`level') `or' grouped
		est local depvar "`dep'"
		exit
	}
	`BY' Estimate `0'
end

program Estimate, eclass byable(recall)
	syntax varlist(min=2) [if] [in] [, CLuster(varname) /*
		*/ OFFset(varname) Level(cilevel) or /*
		*/ LOg SCore(string) *]
	marksample touse

	qui count if `touse'
	if r(N)==0 { error 2000 } 

	tokenize `varlist'
	cap assert `1' == int(`1') if `touse'
	if _rc {
		di as err "`1' is not integer valued"
		exit 459
	}
	cap assert `2' == int(`2') if `touse'
	if _rc {
		di as err "`2' is not integer valued"
		exit 459
	}

	if "`log'"=="" { local log "nolog" } 

	if "`offset'" ~= "" { local offopt "offset(`offset')" }
	if "`cluster'"~= "" { local clopt "cluster(`cluster')" }

	if `"`score'"'~= "" {
		di as err "score() not allowed with blogit"
		exit 198
	}

	preserve 
	quietly { 
		keep if `touse'
		keep `varlist' `cluster' `offset'
		confirm new var _outcome
		tokenize `varlist'
		local lhs "`1' `2'"

		local k = _N
		local k1 = _N + 1
		expand =2, clear

		tempvar pop
		gen byte _outcome=0 in 1/`k'
		replace _outcome=1 in `k1'/l
		gen `pop'=`2'-`1' in 1/`k'
		replace `pop'=`1' in `k1'/l
		mac shift 2
	}
	logit _outcome `*' [freq=`pop'], level(`level') `or' /*
		*/ `options' `log' `clopt' `offopt' grouped

	/* the e() stuff is inherited from -logit- except e(cmd) */
	/* double save in S_E_<stuff> and e() */
	est local cmd
	est local wexp
	est local wtype
	est local depvar "`lhs'"
	est local predict "glogit_p"
	est local estat_cmd ""		/* override what logit set */
	est local title "Logistic regression for grouped data"
	
	global S_E_nobs = e(N)
	global S_E_ll = e(ll)
	global S_E_mdf = e(df_m)
	global S_E_cmd "blogit"
	restore
	est repost, esample(`touse')
	est local cmd "blogit"
end