bprobit.ado

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

*! version 3.3.2  05jan2005
program define bprobit, eclass by(onecall)
	if _by() {
		local BY `"by `_byvars'`_byrc0':"'
	}
	`BY' _vce_parserun bprobit, jkopts(nocount) : `0'
	if "`s(exit)'" != "" {
		exit
	}

	version 6, missing
	if replay() {
		if "`e(cmd)'"!="bprobit" { error 301 }
		if _by() { error 190 }
		syntax [, Level(cilevel) ]
		loc dep "`e(depvar)'"
		est local depvar "_outcome"
		probit, level(`level') grouped
		est local depvar "`dep'"
		exit
	}
	`BY' Estimate `0'
end

program Estimate, eclass byable(recall)
	syntax varlist(min=2) [if] [in] [, CLuster(varname) /*
		*/ OFFset(varname) Level(cilevel) /*
		*/ LOg SCore(string) *]
	marksample touse 

	qui count if `touse'
	if r(N)==0 { error 2000 }

 	tokenize `varlist'
        cap assert `1' == int(`1') if `touse'
        if _rc {
                di as err "`1' is not integer valued"
                exit 459 
        }
        cap assert `2' == int(`2') if `touse'
        if _rc {
                di as err "`2' is not integer valued"
                exit 459
        }

	if "`log'"=="" { local log "nolog" } 

	if "`offset'" ~= "" { local offopt "offset(`offset')" }
	if "`cluster'"~= "" { local clopt "cluster(`cluster')" }
 
 	if `"`score'"'~= "" {
 		di as err "score() not allowed with bprobit"
 		exit 198
 	}

	preserve
	quietly {
		keep if `touse'
		keep `varlist' `cluster' `offset'
		confirm new var _outcome
		tokenize `varlist'
		local lhs "`1' `2'"

		local k = _N
		local k1 = _N + 1

		tempvar pop
		quietly expand =2, clear
		gen byte _outcome=0 in 1/`k'
		replace _outcome=1 in `k1'/l
		gen `pop'=`2'-`1' in 1/`k'
		replace `pop'=`1' in `k1'/l
		mac shift 2
	}
	probit _outcome `*' [freq=`pop'], level(`level') `options' `log' /*
		*/ `clopt' `offopt' grouped

	/* the e() stuff is inherited from -probit- except e(cmd) */
	/* double save in S_E_<stuff> and e() */
	est local cmd
	est local estat_cmd ""	/* override what probit set */
	est local wexp
	est local wtype
	est local depvar "`lhs'"
	est local predict "gprobi_p"
	est local title "Probit regression for grouped data"
	
	global S_E_nobs=e(N)
	global S_E_ll=e(ll)
	global S_E_mdf=e(df_m)
	global S_E_cmd "bprobit"
	restore
	est repost, esample(`touse')
	est local cmd "bprobit"
end