bstat.ado

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

*! version 3.1.4  24feb2005
program bstat
	// version control
	if _caller() < 9 {
		bstat_8 `0'
		exit
	}

	version 9

	if !inlist("bootstrap",`"`e(cmd)'"',`"`e(prefix)'"') {
		Estimate `0'
		exit
	}

	syntax [anything] [using/] [if] [in] [, 	///
		accel(passthru)				///
		Stat(passthru)				///
		n(passthru)				///
		*					///
	]

	if `"`anything'`using'`if'`in'`accel'`stat'`n'"' != "" {
		Estimate `0'
	}
	else	_prefix_display `0'
end

program Estimate, eclass
	// check syntax
	syntax [anything] [using] [if] [in] [,	 	///
		accel(passthru)				///
		Stat(passthru)				///
		MSE					///
		Level(cilevel)				///
		n(passthru)				///
		notable					///
		TItle(string asis)			///
		noHeader				///
		noLegend				///
		Verbose					///
	]

	local diopts		///
		`table'		///
		`header'	///
		`legend'	///
		`verbose'	///
		// blank

	// compute results
	_bs_sum `anything' `using' `if' `in', ///
		`accel' `stat' `n' `mse' level(`level')

	// save results
	tempname b V
	matrix `b' = r(b)
	matrix `V' = r(V)
	ereturn post `b' `V', obs(`r(N)')
	_r2e, xmat(b V)
	ereturn scalar k_extra = 0
	ereturn scalar k_aux = 0
	ereturn local predict _no_predict
	ereturn local prefix bootstrap
	ereturn local cmd bstat
	if `"`title'"' != "" {
		ereturn local title `"`title'"'
	}
	else {
		ereturn local title "Bootstrap results"
	}

	// display results
	_prefix_display, `diopts'
end

exit