anova_estat.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
	anova_estat

*!  VERSION 1.0.2  31mar2005

	***
	USE EXTREME CARE WHEN CHANGING CONTROL NAMES. The names used
	in this file have external dependencies in estat_vce_pr.idlg.
	This also applies when cloning this file.

*/

VERSION 9.0

INCLUDE _std_large
DEFINE _dlght 330
INCLUDE header

HELP hlp1, view("help anova postestimation")
RESET res1

DIALOG main, label("estat - Postestimation tools for anova") tabtitle("Main")
BEGIN
  TEXT     tx_subcmd		_lft	_top	_cwd1	.,		///
  	label("Reports and statistics: (subcommand)")
  LISTBOX  lb_subcmd		@	_ss	_iwd	70,		///
  	contents(main_subcommand_contents)				///
  	values(main_subcommand_values)					///
  	onselchangelist(main_subcommand_scripts)

  DEFINE holdy 110
  // hettest options
  TEXT     tx_var		_lft	holdy	_iwd	.,		///
	label("Variables: (optional)")
  VARLIST  vl_var		@	_ss	@	.,		///
	label("Variables")
  CHECKBOX ck_mtest    		_lft	_ls	_iwd	_ht4,		///
	label("Perform multiple testing")  groupbox			///
	onclickon(script main_adjustment_on)				///
	onclickoff(script main_adjustment_off)
  TEXT     tx_adjustment	_ilft	_ss	_inwd	.,		///
  	label("P-value adjustment:")
  COMBOBOX cb_adjustment	@	_ss     160	.,		///
	label("Multiple testing adjustment")				///
	dropdownlist default(noadjust)					///
	contents(adjustment_methods)					///
	values(adjustment_values)
  // ovtest options
  CHECKBOX ck_rhs		_lft	holdy	_iwd	.,		///
	option(rhs)							///
	label("Use powers of the right-hand-side variables in the test")

  // Information criteria
  TEXT     tx_icnote		_lft	holdy	_iwd	.,		///
  	label("Click OK or Submit to display the AIC and BIC information criteria")

  // Summarize options
  GROUPBOX gb_eqlist            _lft    holdy	_iwd	_ht6h,		///
  	label("Summarize")
  RADIO    rb_default		_ilft	_ss	_inwd	.,		///
  	first label("Use all variables involved in the estimation")	///
  	onclickon(main.vl_spec.disable)
  RADIO    rb_spec		@	_ss	@	.,		///
	onclickon(main.vl_spec.enable) last				///
	label("Use variables and optional equation names:")
  VARLIST  vl_spec	      _indent2	_ss	_inwd	.,		///
	label("Use variables and optional equation names")
  CHECKBOX ck_equation      	_lft	+45	_iwd	.,		///
	option(equation)						///
	label("Display summary by equation")
  CHECKBOX ck_labels		@	_ms	@	.,		///
  	label("Display variable labels")				///
  	option(labels)
  CHECKBOX ck_noheader		_lft	_ms	_iwd	.,		///
	option(noheader)						///
	label("Suppress the header")
  CHECKBOX ck_noweights		@	_ms	@	.,		///
	option(noweights)						///
	label("Ignore weights")

  INCLUDE estat_vce
END

INCLUDE estat_vce_pr

SCRIPT main_adjustment_on
BEGIN
	main.cb_adjustment.enable
	main.tx_adjustment.enable
	main.tx_var.setlabel "Variables: (required)"
END
SCRIPT main_adjustment_off
BEGIN
	main.cb_adjustment.disable
	main.tx_adjustment.disable
	main.tx_var.setlabel "Variables: (optional)"
END

LIST adjustment_methods
BEGIN
	"None"
	"Bonferroni's adjustment"
	"Holm's adjustment"
	"Sidak's adjustment"
END

LIST adjustment_values
BEGIN
	mtest
	mtest(bonferroni)
	mtest(holm)
	mtest(sidak)
END

LIST main_subcommand_contents
BEGIN
  	 "Tests for heteroskedasticity (hettest)"
	 "Ramsey regression specification-error test for omitted variables (ovtest)"
 	 "Information criteria (ic)"
 	 "Summarize estimation sample (summarize)"
 	 "Covariance matrix estimates (vce)"
END

LIST main_subcommand_values
BEGIN
	hettest
	ovtest
	ic
	summarize
	vce
END

LIST main_subcommand_scripts
BEGIN
	script sel_hettest
	script sel_ovtest
	script sel_ic
	script sel_summarize
	script sel_vce
END

SCRIPT sel_hettest
BEGIN
	main.tx_icnote.hide
	script main_summ_off
	program vce_off
	script hettest_on
END

SCRIPT sel_ovtest
BEGIN
	main.tx_icnote.hide
	script main_summ_off
	program vce_off
	script ovtest_on
END

SCRIPT sel_ic
BEGIN
	main.tx_icnote.show
	script main_summ_off
	program vce_off
	script non_basic_opt_off
END

SCRIPT sel_summarize
BEGIN
	main.tx_icnote.hide
	script main_summ_on
	program vce_off
	script non_basic_opt_off
END

SCRIPT sel_vce
BEGIN
	main.tx_icnote.hide
	program vce_on
	script main_summ_off
	script non_basic_opt_off
END

SCRIPT hettest_on
BEGIN
	main.ck_rhs.hide
	main.tx_var.show
	main.vl_var.show
	main.ck_mtest.show
	main.tx_adjustment.show
	main.cb_adjustment.show
END

SCRIPT ovtest_on
BEGIN
	main.ck_rhs.show
	main.tx_var.hide
	main.vl_var.hide
	main.ck_mtest.hide
	main.tx_adjustment.hide
	main.cb_adjustment.hide
END

SCRIPT non_basic_opt_off
BEGIN
	main.ck_rhs.hide
	main.tx_var.hide
	main.vl_var.hide
	main.ck_mtest.hide
	main.tx_adjustment.hide
	main.cb_adjustment.hide
END

SCRIPT main_summ_on
BEGIN
	main.ck_equation.show
	main.ck_labels.show
	main.ck_noheader.show
	main.ck_noweights.show
	main.gb_eqlist.show
	main.rb_default.show
	main.rb_spec.show
	main.vl_spec.show
END

SCRIPT main_summ_off
BEGIN
	main.ck_equation.hide
	main.ck_labels.hide
	main.ck_noheader.hide
	main.ck_noweights.hide
	main.gb_eqlist.hide
	main.rb_default.hide
	main.rb_spec.hide
	main.vl_spec.hide
END

PROGRAM vl_output
BEGIN
	put main.vl_spec
END

PROGRAM vl_eq_output
BEGIN
	put main.vl_eq
END

PROGRAM command
BEGIN
	put "estat "
	put main.lb_subcmd
	if main.rb_spec {
		require main.vl_spec
		put " " main.vl_spec
	}
	if main.ck_mtest {
		require main.vl_var
	}
	varlist [main.vl_var]
	beginoptions
		// non-basic options
		if main.ck_mtest {
			put " " main.cb_adjustment
		}
		option main.ck_rhs

		// Summarize options
		option main.ck_equation
		option main.ck_labels
		option main.ck_noheader
		option main.ck_noweights
		put /program vce_output
	endoptions
END