anova_estat.ado

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

*! version 1.0.0  04feb2005
program anova_estat, rclass
	version 9

	if "`e(cmd)'" != "anova" {
		error 301
	}

	gettoken key rest : 0, parse(", ")
	local lkey = length(`"`key'"')
	if `"`key'"' == substr("ovtest",1,max(3,`lkey')) {
		ovtest `rest'
	}
	else if `"`key'"' == substr("hettest",1,max(4,`lkey')) {
		AnovaHetTest `rest'
	}
	else if `"`key'"' == substr("summarize",1,max(2,`lkey')) {
		AnovaSumm `rest'
	}
	else {
		estat_default `0'
	}
	return add
end

program AnovaHetTest, rclass
	// -rhs- option not allowed for -hettest- after -anova-
	capture syntax [anything] , Rhs [*]
	if _rc == 0 {
		di as err "option rhs not allowed"
		exit 198
	}
	else {
		if "`anything'" == "" {
			syntax [, Mtest Mtest2(passthru) ]
			if `"`mtest'`mtest2'"' != "" {
				di as err ///
				`"varlist required with `mtest'`mtest2' option"'
				exit 198
			}
		}
		hettest `0'
	}
	return add
end

program AnovaSumm, rclass
	// handle the varlist since names are not on the e(b) matrix stripe

	syntax [anything(name=vlist)] [, * ]

	if `"`vlist'"' == "" {
		local vlist `e(depvar)' `e(varnames)'
	}

	estat_summ `vlist', `options'

	return add
end