anova.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
    anova.dlg

*!  VERSION 1.1.1  31mar2005

    keyword:  eclass

*/

VERSION 9.0

INCLUDE _std_large
INCLUDE _ht310
INCLUDE header
HELP hlp1, view("help anova")
RESET res1

DIALOG main, tabtitle("Model")					///
	label("anova - Analysis of variance and covariance")
BEGIN
  TEXT     tx_dv        _lft      _top      _iwd      .,	///
	label("Dependent variable:")
  VARNAME  vn_dv        @         _ss       _vnwd     .,	///
	label("Dependent variable")

  BUTTON   bu_examples  _lft4_4   _ms       _cwd4_1   .,	///
	push("script examples")					///
	label("Examples...")
  TEXT     tx_terms     _lft      +5        _vlwd     .,	///
	label("Model:")
  VARLIST  vl_terms     @         _ss       _iwd      .,	///
	label("Model")

  GROUPBOX gb_modvars   @         _ls       _comb4_1  _ht15h,	///
	label("Model variables")
  DEFINE   holdy @y
  RADIO    rb_allcat    _indent   _ss       _inwd     ., first	///
	onclickon(script allcat)				///
	label("All categorical")
  RADIO    rb_cont      @         _ss       @         .,	///
	onclickon(script cont)					///
	label("Categorical except the following continuous variables:")
  VARLIST  vl_cont      @         _ss       @         .,	///
	option(continuous)					///
	label("Categorical except the following continuous variables")
	// -class()- not included since it is a synonym for -category()-
  RADIO    rb_category  @         _ms       @         ., last	///
	onclickon(script category)				///
	label("Continuous except the following categorical variables:")
  VARLIST  vl_category  @         _ss       @         .,	///
	option(category)					///
	label("Continuous except the following categorical variables")

  CHECKBOX ck_repeated  @         _ls       @         .,	///
	onclickon(script rep_on)				///
	onclickoff(script rep_off)				///
	label("Repeated-measures variables")
  VARLIST  vl_repeated  _indent2  _ss       _inwd     .,	///
	option(repeated)					///
	label("Repeated-measures variables")

  GROUPBOX gb_ss        _lft4_4   holdy     _cwd4_1   _ht4,	///
	label("Sums of squares")
  RADIO    rb_partial   _indent   _ss       _inwd     ., first	///
	option(partial)						///
	label("Partial")
  RADIO    rb_seq       @         _ss       @         ., last	///
	option(sequential)					///
	label("Sequential")

  CHECKBOX ck_noconst   _lft4_4   _xls      _cwd4_1   .,	///
	option(noconstant)					///
	label("Suppress")
  TEXT     tx_noconst   _indent2  _vss      _cwd4_5   .,	///
	label("constant term")

END

DIALOG adv, tabtitle("Adv. model")
BEGIN
  GROUPBOX gb_advrep    _lft      _top      _iwd      _ht15,	///
	label("Advanced repeated-measures options")

  TEXT     tx_bse       _ilft     _ss       _ibwd     .,	///
	label("Between-subjects error term:")
  VARLIST  vl_bse       @         _ss       @         .,	///
	option(bse)						///
	label("Between-subjects error term")

  TEXT     tx_bseunit   @         _ls       @         .,	///
	label("Variable representing lowest unit in the between-subjects error term:")
  VARNAME  vn_bseunit   @         _ss       _vnwd     .,	///
	option(bseunit)						///
	label("Variable representing lowest unit in the between-subjects error term")

  TEXT     tx_grouping  @         _ls       _ibwd     .,	///
	label("Grouping variable for computing pooled covariance matrix:")
  VARNAME  vn_grouping  @         _ss       _vnwd     .,	///
	option(grouping)					///
	label("Grouping variable for computing pooled covariance matrix")
END


INCLUDE byifin
INCLUDE weights_fa


DIALOG rpt, tabtitle("Reporting")
BEGIN
  RADIO    rb_anova     _lft      _top      _iwd      ., first	///
	option(NONE)						///
	label("Display anova table")
  RADIO    rb_regress   @         _ss       @         .,	///
	option(regress)						///
	label("Display regression table")
  RADIO    rb_reganova  @         _ss       @         .,	///
	option(regress anova)					///
	label("Display anova and regression table")
  RADIO    rb_noanova   @         _ss       @         ., last	///
	option(noanova)						///
	label("Suppress anova and regression table")

  CHECKBOX ck_detail    @         _ls       @         .,	///
	option(detail)						///
	label("Show mapping from values to level numbers for categorical variables")
END


SCRIPT examples
BEGIN
	view help anova_example##|_new
END

SCRIPT allcat
BEGIN
	main.vl_cont.disable
	main.vl_category.disable
END

SCRIPT cont
BEGIN
	main.vl_cont.enable
	main.vl_category.disable
END

SCRIPT category
BEGIN
	main.vl_cont.disable
	main.vl_category.enable
END

SCRIPT rep_on
BEGIN
	main.vl_repeated.enable
	adv.gb_advrep.enable
	adv.tx_bse.enable
	adv.vl_bse.enable
	adv.tx_bseunit.enable
	adv.vn_bseunit.enable
	adv.tx_grouping.enable
	adv.vn_grouping.enable
END

SCRIPT rep_off
BEGIN
	main.vl_repeated.disable
	adv.gb_advrep.disable
	adv.tx_bse.disable
	adv.vl_bse.disable
	adv.tx_bseunit.disable
	adv.vn_bseunit.disable
	adv.tx_grouping.disable
	adv.vn_grouping.disable
END


PROGRAM command
BEGIN
	INCLUDE _by_pr
	put "anova "
	varlist main.vn_dv [main.vl_terms]
	INCLUDE _weights_pr
	INCLUDE _ifin_pr
	beginoptions
		if main.rb_cont {
			require main.vl_cont
			optionarg main.vl_cont
		}
		if main.rb_category {
			require main.vl_category
			optionarg main.vl_category
		}
		if main.ck_repeated {
			require main.vl_repeated
			optionarg main.vl_repeated
		}
		option radio(main rb_partial rb_seq)
		option main.ck_noconst
		option radio(rpt rb_anova rb_regress rb_reganova rb_noanova)
		option rpt.ck_detail
		optionarg adv.vl_bse
		optionarg adv.vn_bseunit
		optionarg adv.vn_grouping
	endoptions
END