zinb.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  zinb

*!  VERSION 1.1.2  21mar2005

  keyword:  eclass

*/

VERSION 9.0

INCLUDE _std_large
INCLUDE _ht330
INCLUDE header

HELP hlp1, view("help zinb")
RESET res1

DIALOG main, label("zinb -  Zero-inflated negative binomial regression")/*
		*/ tabtitle("Model")
BEGIN
  INCLUDE _dviv

  CHECKBOX ck_nocons @         _ms       @         .,			/*
		*/ label("Suppress constant term")			/*
		*/ option("noconstant")					/*
		*/

  RADIO    rb_inflate  _lft        _ls       _vnwd        .,		/*
  		*/ label("Inflation variables:")			/*
  		*/ onclickon(script consoff)				/*
  		*/ first default(1)
  RADIO    rb_cons     _vlx     @       _vlwd        .,		/*
  		*/ label("Constant inflation")				/*
  		*/ onclickon(script conson)				/*
  		*/ option(_cons)					/*
  		*/ last
  VARLIST  vl_inflate  _lft        _ss       _iwd       .,		/*
		*/ label("Inflation variables")				/*
		*/ allowcat						/*
		*/


  GROUPBOX gb_opt    _lft      _ls       _iwd      _ht15,		/*
		*/ label("Options")					/*
		*/
  RADIO    rb_expose _ilft     _ss       _cwd3_2   .,			/*
		*/ label("Exposure variable:")				/*
		*/ first						/*
		*/ clickon("script expose")				/*
		*/
  RADIO    rb_offset _lft3_2   @         @         .,			/*
		*/ label("Offset variable:")				/*
		*/ last							/*
		*/ clickon("script offset")				/*
		*/

  VARNAME  vn_expose _ilft     _ss       @         .,			/*
		*/ label("Exposure variable")				/*
		*/ option("exposure")					/*
		*/
  VARNAME  vn_offset _lft3_2   @         @         .,			/*
		*/ label("Offset variable")				/*
		*/ option("offset")					/*
		*/

  TEXT     tx_infoff _ilft     _ls       _cwd3_2     .,			/*
		*/ label("Inflation offset variable:")			/*
		*/
DEFINE y @y
  VARNAME  vn_infoff @         _ss       _cwd3_2     .,			/*
		*/ label("Inflation offset variable")			/*
		*/ option("offset")

  DEFINE _x _lft3_2
  DEFINE _cx _comb3_2
  DEFINE _y y
  INCLUDE _constraints

  GROUPBOX gb_zero   _ilft     _ls       _ibwd     _ht2,		/*
  		*/ label("Model for characterizing zeros")
  RADIO    rb_logit  _indent   _ss       _cwd3     .,			/*
		*/ label("logit")					/*
		*/ option("NONE")					/*
		*/ first						/*
		*/
  RADIO    rb_probit _lft2     @         @         .,			/*
		*/ label("probit")					/*
		*/ option("probit")					/*
		*/ last							/*
		*/
END

SCRIPT conson
BEGIN
	main.vl_inflate.disable
	main.vn_infoff.disable
END

SCRIPT consoff
BEGIN
	main.vl_inflate.enable
	main.vn_infoff.enable
END

SCRIPT expose
BEGIN
	main.vn_expose.enable
	main.vn_offset.disable
END

SCRIPT offset
BEGIN
	main.vn_expose.disable
	main.vn_offset.enable
END

INCLUDE byifin
INCLUDE weights_fpi
INCLUDE se

SCRIPT PREINIT
BEGIN
	script se_createAsJknifeBstrapML
END

DIALOG rpt, tabtitle("Reporting")
BEGIN
  DEFINE _x _lft
  DEFINE _cx _spr2b
  DEFINE _y _top
  INCLUDE _sp_level

  RADIO    rb_default _lft     _ls       _cwd1     .,			/*
  		*/ label("Report coefficients (default)") 		/*
  		*/ first
  RADIO    rb_irr     @        _ss       @         .,			/*
		*/ label("Report incidence-rate ratios")		/*
		*/ option("irr") 					/*
		*/ last

  GROUPBOX gb_tests  _lft      +35       _iwd      _ht4,		/*
  		*/ label("Additional test statistics")
  CHECKBOX ck_vuong  _ilft     _ss       _cwd2     .,			/*
		*/ label("Perform Vuong test")				/*
		*/ option("vuong")					/*
		*/
  CHECKBOX ck_zip    @         _ss       @         .,			/*
		*/ label("Perform zip likelihood-ratio test")		/*
		*/ option("zip")					/*
		*/
END

PROGRAM rpt_output
BEGIN
	optionarg /hidedefault rpt.sp_level
	option rpt.rb_irr
	option rpt.ck_vuong
	option rpt.ck_zip
END

INCLUDE max_ml

PROGRAM subcommand
BEGIN
	option main.rb_cons
	require main.vl_inflate
	put main.vl_inflate
	beginoptions
		optionarg main.vn_infoff
	endoptions
END

PROGRAM command
BEGIN
	INCLUDE _by_pr
	allowxi
	put "zinb "
	varlist main.vn_dv [main.vl_iv]
	if !main.vl_iv & main.ck_nocons {
	  stopbox stop `""Suppress constant term" is selected without independent variables."'
	}
	INCLUDE _weights_pr
	INCLUDE _ifin_pr
	beginoptions
		option main.ck_nocons
		put "inflate("
		put /program subcommand
		put ") "
		optionarg main.vn_expose
		optionarg main.vn_offset
		INCLUDE _constraints_main_pr
		option radio(main rb_logit rb_probit)
		put " " /program se_output
		put " " /program rpt_output
		put " " /program max_output
	endoptions
END