mlogit.ado

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

*! version 1.0.7  24feb2005
program define mlogit, eclass sortpreserve byable(onecall) ///
		prop(rrr svyb svyj svyr)
	version 9, missing
	local version : di "version " string(_caller()) ", missing :"

	if _by() {
		local BY `"by `_byvars'`_byrc0':"'
	}
	`version' `BY' _vce_parserun mlogit : `0'
	if "`s(exit)'" != "" {
		exit
	}
	if replay() {
		if "`e(cmd)'" != "mlogit" {
			error 301
		}
		if _by() {
			error 190
		}
		`version' Display `0'
		exit
	}
	syntax [anything] [if] [in] [fw iw pw aw] [, * ]
	`version' `BY' _mlogit `0'
	ereturn local title "Multinomial logistic regression"
	ereturn local footnote "mlogit_footnote"
	ereturn local baselab : label (`e(depvar)') `e(basecat)'
end

program Display
	version 9
	syntax [, Level(cilevel) * ]
	local version : di "version " string(_caller()) ":"
	if "`e(prefix)'" != "" {
		_coef_table_header
		di
		_coef_table, level(`level') `options'
		_prefix_footnote
	}
	else	`version' _mlogit, level(`level') `options'
end

exit