mhodds.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
	mhodds

*!  VERSION 1.0.1  29jul2004

*/

VERSION 8.0

INCLUDE _std_medium
INCLUDE header

HELP hlp1, view("help mhodds")
RESET res1

DIALOG main, label("mhodds - Case-control studies") tabtitle("Main")
BEGIN
  TEXT     tx_var     _lft      _top      _cwd1         .,		/*
		*/ label("Case exposed variable:")
  VARNAME  vn_var        @       _ss      _vnwd         .,		/*
		*/ label("Case exposed variable")

  TEXT     tx_val    _lft2      _top      _cwd1         .,		/*
		*/ label("Control exposed variable:")
  VARNAME  vn_val        @       _ss      _vnwd         .,		/*
		*/ label("Control exposed variable")
  TEXT     tx_adj      _lft      +35      _iwd          .,		/*
		*/ label("Control for confounding variables: (optional)")
  VARLIST  vl_adj      @         _ss       @	        .,    		/*
		*/ label("Control for confounding variables")
END

INCLUDE ifin
INCLUDE weights_f

DIALOG opt, tabtitle("Options")
BEGIN
  CHECKBOX ck_byopt          _lft      _top      _cwd1     .,		/*
		*/ label("Stratify on variables:")			/*
		*/ clickon("gaction opt.vl_byopt.enable")		/*
		*/ clickoff("gaction opt.vl_byopt.disable")
  VARLIST  vl_byopt          @	       _ss       _iwd      .,    	/*
		*/ option("by")						/*
		*/ label("Stratify on variables")
  CHECKBOX ck_bin            @         _ls       _cwd1	   .,		/*
		*/ label("Number of subjects variable:")		/*
		*/ clickon("gaction opt.vn_bin.enable")			/*
		*/ clickoff("gaction opt.vn_bin.disable")
  VARNAME  vn_bin            @         _ss       _vnwd	   .,		/*
		*/ option("binomial")					/*
		*/ label("Number of subjects variable")
  CHECKBOX ck_compare        @         _ls       _iwd      .,		/*
		*/ label("Override categories of the control variable")	/*
		*/ clickon("script compare_on")				/*
		*/ clickoff("script compare_off")
  EDIT     en_var1           @         _ss       _en7wd    .,		/*
		*/ label("Numerator")					/*
		*/ numonly
  TEXT     tx_var1           _en7sep   @         _vnrb     .,		/*
		*/ label("Numerator")
  EDIT     en_var2           _lft      _ms       _en7wd    .,		/*
		*/ label("Denominator")					/*
		*/ numonly
  TEXT     tx_var2           _en7sep   @         _vnrb     .,		/*
		*/ label("Denominator")
  DEFINE _x _lft
  DEFINE _y _xls
  DEFINE _cx _spr
  INCLUDE _sp_level
END

SCRIPT compare_on
BEGIN
	opt.en_var2.enable
	opt.tx_var2.enable
	opt.en_var1.enable
	opt.tx_var1.enable
END

SCRIPT compare_off
BEGIN
	opt.en_var2.disable
	opt.tx_var2.disable
	opt.en_var1.disable
	opt.tx_var1.disable
END

PROGRAM command
BEGIN
	put "mhodds "
	varlist main.vn_var
	varlist main.vn_val
	varlist [main.vl_adj]
	INCLUDE _weights_pr
	INCLUDE _ifin_pr
	beginoptions
		if opt.ck_byopt {
			require opt.vl_byopt
			optionarg opt.vl_byopt
		}
		if opt.ck_bin {
			require opt.vn_bin
			optionarg opt.vn_bin
		}
		if opt.ck_compare {
			require opt.en_var1 opt.en_var2
			put "compare("
			put opt.en_var1
			put ","
			put opt.en_var2
			put ")"
		}
		INCLUDE _level_opt_pr
	endoptions
END