mdslong.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
	mdslong

*!  VERSION 1.0.0  24mar2005

*/

VERSION 9.0

INCLUDE _std_large
DEFINE _dlght 350
INCLUDE header
HELP hlp1, view("help mdslong")
RESET res1

DIALOG main, label("mdslong - Multidimensional scaling of proximity data")	///
	tabtitle("Model")
BEGIN
  TEXT     tx_dv		_lft	_top	_vnwd	.,			///
  	label("Dependent variable:")
  DEFINE holdy @y
  VARNAME  vn_dv		@	_ss	_cwd3_1	.,			///
  	label("Dependent variable")

  TEXT     tx_idvar1	       _lft3_02	_top	_vnwd	.,			///
  	label("ID variable 1:")
  VARNAME  vn_idvar1		@	_ss	_cwd3_1	.,			///
  	label("ID variable 1")
  TEXT     tx_idvar2	       _lft3_03	_top	_vnwd	.,			///
  	label("ID variable 2:")
  VARNAME  vn_idvar2		@	_ss	_cwd3_1	.,			///
  	label("ID variable 2")

  GROUPBOX gb_convertsim	_lft	_ls	_iwd	_ht6,			///
	label("Proximity")
  RADIO rb_default		_ilft	_ss	_ibwd	.,	first		///
	label("Dissimilarity (default)")
  RADIO rb_standard		@	_ss	@		.,		///
	option(s2d(standard))							///
	label("Convert similarity to dissimilarity using d(ij)=sqrt(s(ii)+s(jj)-2s(ij))")
  RADIO rb_oneminus		@	_ss	@	.,	last		///
	label("Convert similarity to dissimilarity using d(ij)=1-s(ij)")	///
	option(s2d(oneminus))

  CHECKBOX ck_force		_lft	_xls	_iwd	.,			///
	label("Correct problems with the supplied proximity information")	///
	option(force)
  SPINNER  sp_dim		_lft	_ls	_spwd	.,			///
	label("Configuration dimensions")					///
	min(1)									///
	max(10000)								///
	default(2)								///
	option(dimension)
  TEXT     tx_dim		_spsep	@	_cksprb	.,			///
	label("Dimension of the approximating configuration")
  CHECKBOX ck_addconstant	_lft	_ls	_iwd	.,			///
	label("Make distance matrix positive definite")				///
	option(addconstant)
END

INCLUDE byifin

DIALOG report, tabtitle("Reporting")
BEGIN
  SPINNER  sp_neigen		_lft	_top	_spwd	.,			///
	label("Dimensions")							///
	min(1)									///
	max(10000)								///
	default(10)								///
	option(neigen)
  TEXT     tx_neigen		_spsep	@	_spr	.,			///
	label("Maximum number of eigenvalues to display")
  CHECKBOX ck_config		_lft	_ls	_iwd	.,			///
	label("Display table with configuration coordinates")			///
	option(config)
  CHECKBOX ck_noplot		@	_ms	@	.,			///
	label("Suppress configuration plot")					///
	option(noplot)
END

PROGRAM command
BEGIN
	INCLUDE _by_pr
	put "mdslong "
	require main.vn_dv
	put main.vn_dv
	INCLUDE _ifin_pr
	beginoptions
		require main.vn_idvar1
		put "id(" main.vn_idvar1 " "
		require main.vn_idvar2
		put main.vn_idvar2
		put ") "
		option main.rb_standard
		option main.rb_oneminus
		option main.ck_force
		optionarg /hidedefault main.sp_dim
		option main.ck_addconstant
		optionarg /hidedefault report.sp_neigen
		option report.ck_config
		option report.ck_noplot
	endoptions
END