mfp.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
    mfp.dlg

*!  VERSION 1.1.0  20dec2004

*/

VERSION 9.0

INCLUDE _std_large
INCLUDE _ht320
INCLUDE header

HELP hlp1, view("help mfp")
RESET res1

DIALOG main, label("mfp - Multivariable fractional polynomial models")	/*
		*/ tabtitle("Model")
BEGIN
  INCLUDE _dviv

  GROUPBOX gb_reg    _lft      _xls      _iwd      _ht12h, 		/*
		*/ label("Available regression commands")		/*
		*/
  TEXT     tx_reg    _ilft     _ss       _ibwd     .,			/*
  	*/label("Commands are not necessarily compatible with all weights.")/*
  		*/
  RADIO    rb_clogit _ilft     _ms       _cwd4_2   .,			/*
		*/ label("clogit *")					/*
		*/ clickon(script clogit_on)				/*
		*/ clickoff(script clogit_off)				/*
		*/ first						/*
		*/ option("clogit")					/*
		*/
  RADIO    rb_glm    _ilft4_2  @         @         .,			/*
		*/ label("glm")						/*
		*/ clickon(main.vn_dv.enable)				/*
		*/ option("glm")					/*
		*/
  GROUPBOX gb_streg  _ilft4_3  @         _cwd3     _ht6,		/*
		*/ label("streg")
  TEXT     tx_mark   _indent   @         0         0,
  DEFINE marker @x
  RADIO    rb_logist _ilft     _ss       _cwd4_2   .,			/*
		*/ label("logistic")					/*
		*/ clickon(main.vn_dv.enable)				/*
		*/ option("logistic")					/*
		*/
  RADIO    rb_logit  _ilft4_2  @         @         .,			/*
		*/ label("logit")					/*
		*/ clickon(main.vn_dv.enable)				/*
		*/ option("logit")					/*
		*/
  RADIO    rb_ereg   marker    @         _cwd4_5   .,			/*
		*/ label("ereg")					/*
		*/ clickon(main.vn_dv.disable)				/*
		*/ option("streg")					/*
		*/
  RADIO    rb_gamma  _iilft4_4 @         @         .,			/*
		*/ label("gamma")					/*
		*/ clickon(main.vn_dv.disable)				/*
		*/ option("streg")					/*
		*/
  RADIO    rb_pois   _ilft     _ss       _cwd4_2   .,			/*
		*/ label("poisson")					/*
		*/ clickon(main.vn_dv.enable)				/*
		*/ option("poisson")					/*
		*/
  RADIO    rb_probit _ilft4_2  @         @         .,			/*
		*/ label("probit")					/*
		*/ clickon(main.vn_dv.enable)				/*
		*/ option("probit")					/*
		*/
  RADIO    rb_gomp   marker    @         _cwd4_5   .,			/*
		*/ label("gompertz")					/*
		*/ clickon(main.vn_dv.disable)				/*
		*/ option("streg")					/*
		*/
  RADIO    rb_llogis _iilft4_4 @         @         .,			/*
		*/ label("llogistic")					/*
		*/ clickon(main.vn_dv.disable)				/*
		*/ option("streg")					/*
		*/
  RADIO    rb_qreg   _ilft     _ss       _cwd4_2   .,			/*
		*/ label("qreg")					/*
		*/ clickon(main.vn_dv.enable)				/*
		*/ option("qreg")					/*
		*/
  RADIO    rb_reg    _ilft4_2  @         @         .,			/*
		*/ label("regress")					/*
		*/ clickon(main.vn_dv.enable)				/*
		*/ option("regress")					/*
		*/
  RADIO    rb_lnorm  marker    @         _cwd4_5   .,			/*
		*/ label("lnormal")					/*
		*/ clickon(main.vn_dv.disable)				/*
		*/ option("streg")					/*
		*/
  RADIO    rb_weib   _iilft4_4 @         @         .,			/*
		*/ label("weibull")					/*
		*/ clickon(main.vn_dv.disable)				/*
		*/ option("streg")					/*
		*/
  RADIO    rb_stcox  _ilft     _ss       @         .,			/*
		*/ label("stcox")					/*
		*/ clickon(main.vn_dv.enable)				/*
		*/ option("stcox")					/*
		*/
  RADIO    rb_xtgee  _ilft4_2  @         @         .,			/*
		*/ label("xtgee")					/*
		*/ clickon(main.vn_dv.enable)				/*
		*/ last							/*
		*/ option("xtgee")					/*
		*/
  TEXT     tx_note   _lft      _xls      _iwd      .,			/*
  */ label(`"* NOTE: The -group- option must be specified."')
  TEXT     tx_note2  @         _ss       @         .,			/*
  */ label(`"Use "Other options accepted by chosen regression command" on "Adv. model" tab."')
END

DIALOG opt, label("") tabtitle("Model 2")
BEGIN
  CHECKBOX ck_seq    _lft      _top      _iwd      .,			/*
	*/ label("Use the Royston and Altman model-selection algorithm")/*
		*/ option("sequential")					/*
		*/

  SPINNER  sp_cycles _lft      _ls       _spwd     .,			/*
		*/ min(1)						/*
		*/ max(10000)						/*
		*/ default(5)						/*
		*/ option("cycles")					/*
		*/
  TEXT     tx_cycles _spsep    @         _spr      .,			/*
		*/ label("Maximum number of iteration cycles")		/*
		*/

  SPINNER  sp_dfdef  _lft      _ls       _spwd     .,			/*
		*/ min(1)						/*
		*/ max(1000000)						/*
		*/ default(4)						/*
		*/ option("dfdefault")					/*
		*/
  TEXT     tx_dfdef  _spsep    @         _spr      .,			/*
		*/ label("Default maximum degrees of freedom")		/*
		*/

  TEXT     tx_adjust _lft      _ls       _iwd      .,			/*
*/ label("Adjustment for each predictor: [see help for adjust()]")	/*
		*/
  EDIT     ed_adjust @         _ss       @         .,			/*
		*/ label("Adjustment for each predictor")		/*
		*/ option("adjust")					/*
		*/

  TEXT     tx_alpha  _lft      _ls       _iwd      .,			/*
*/ label("P-values for testing between FP models: [see help for alpha()]")/*
		*/
  EDIT     ed_alpha  @         _ss       @         .,			/*
		*/ label("P-values for testing between FP models")	/*
		*/ option("alpha")					/*
		*/

  TEXT     tx_df     _lft      _ls       _iwd      .,			/*
*/ label("Degrees of freedom for each predictor: [see help for df()]")	/*
		*/
  EDIT     ed_df     @         _ss       @         .,			/*
		*/ label("Degrees of freedom for each predictor")	/*
		*/ option("df")						/*
		*/

  TEXT     tx_powers _lft      _ls       _iwd      .,			/*
	*/ label("List of fractional polynomial powers to use:")	/*
		*/
  EDIT     ed_powers @         _ss       @         .,			/*
		*/ label("List of fractional polynomial powers to use")	/*
		*/ option("powers")					/*
		*/

END

DIALOG adv, label("") tabtitle("Adv. model")
BEGIN
  GROUPBOX gb_xorder _lft      _top      _iwd      _ht2,		/*
	*/ label("Order of entry into the model-selection algorithm")	/*
		*/
  RADIO    rb_xoplus _indent   _ss       _cwd3_2   .,			/*
		*/ label("Most significant first")			/*
		*/ first						/*
		*/ option(NONE)						/*
		*/
  RADIO    rb_xomin  _lft3_2   @         @         .,			/*
		*/ label("Least significant first")			/*
		*/ option("xorder(-)")					/*
		*/
  RADIO    rb_xon    _lft3_3   @         @         .,			/*
		*/ label("Original order")				/*
		*/ last							/*
		*/ option("xorder(n)")					/*
		*/

  TEXT     tx_select _lft      _xls      _iwd      .,			/*
*/ label("Nominal p-values for selection on each predictor: [see help for select()]")	/*
		*/
  EDIT     ed_select @         _ss       @         .,			/*
	*/ label("Nominal p-values for selection on each predictor")	/*
		*/ option("select")					/*
		*/

  TEXT     tx_xpow   _lft      _ls       _iwd      .,			/*
*/ label("Fractional polynomial powers for each predictor: [see help for xpowers()]") /*
		*/
  EDIT     ed_xpow   @         _ss       @         .,			/*
	*/ label("Fractional polynomial powers for each predictor")	/*
		*/ option("xpowers")					/*
		*/

  TEXT     tx_zero   _lft      _ls       _iwd      .,			/*
*/ label("Treat nonpositive values of these predictors as zero when FP transformed:") /*
		*/
  VARLIST  vl_zero   @         _ss       @         .,			/*
*/ label("Treat nonpositive values of these predictors as zero when FP transformed") /*
		*/ option("zero")					/*
		*/

  TEXT     tx_cat0   _lft      _ls       _iwd      .,			/*
*/ label("Add indicator variable for these predictors: [see help for catzero()]") /*
		*/
  VARLIST  vl_cat0   @         _ss       @         .,			/*
		*/ option("catzero")					/*
*/ label("Add indicator variable for these predictors") /*
		*/

  TEXT     tx_regopt _lft      _ls       _iwd      .,			/*
	*/ label("Other options accepted by chosen regression command:")/*
		*/
  EDIT     ed_regopt @         _ss       @         .,			/*
	*/ label("Other options accepted by chosen regression command")/*
		*/
END

SCRIPT clogit_on
BEGIN
	main.vn_dv.enable
	main.tx_note.show
	main.tx_note2.show
END

SCRIPT clogit_off
BEGIN
	main.tx_note.hide
	main.tx_note2.hide
END

INCLUDE ifin
INCLUDE weights_fpai

PROGRAM command
BEGIN
	allowxi
	put "mfp "
	option radio(main rb_clogit rb_ereg rb_gamma rb_glm rb_gomp rb_llogis rb_lnorm rb_logist rb_logit rb_pois rb_probit rb_qreg rb_reg rb_stcox rb_weib rb_xtgee)
	if main.vn_dv {
		put main.vn_dv
	}
	varlist main.vl_iv
	INCLUDE _weights_pr
	INCLUDE _ifin_pr
	beginoptions
		if main.rb_ereg {
			put "distribution(exponential)"
		}
		if main.rb_gamma {
			put "distribution(gamma)"
		}
		if main.rb_gomp {
			put "distribution(gompertz)"
		}
		if main.rb_llogis {
			put "distribution(loglogistic)"
		}
		if main.rb_lnorm {
			put "distribution(lognormal)"
		}
		if main.rb_weib {
			put "distribution(weibull)"
		}
		optionarg opt.ed_adjust
		optionarg opt.ed_alpha
		optionarg /hidedefault opt.sp_cycles
		optionarg opt.ed_df
		optionarg opt.sp_dfdef
		optionarg opt.ed_powers
		optionarg adv.ed_select
		option opt.ck_seq
		option radio(adv rb_xoplus rb_xomin rb_xon)
		optionarg adv.ed_xpow
		optionarg adv.vl_zero
		optionarg adv.vl_cat0
		put adv.ed_regopt
	endoptions
END