manova.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  manova

*! VERSION 1.0.2  31mar2005

  keyword:  eclass
*/

VERSION 8.0

INCLUDE _std_large
INCLUDE _ht310
INCLUDE header
HELP hlp1, view("help manova")
RESET res1

DIALOG main, /*
	*/ label("manova - Multivariate analysis of variance and covariance") /*
	*/ tabtitle("Model")
BEGIN
  TEXT     tx_dv        _lft      _top      _iwd      .,		/*
		*/ label("Dependent variables:")
  VARLIST  vl_dv        @         _ss       @         .,		/*
		*/ label("Dependent variables")

  BUTTON   bu_examples  _lft4_4   _ms       _cwd4_1   .,		/*
		*/ push("script examples")				/*
		*/ label("Examples...")
  TEXT     tx_terms     _lft      +5        _vlwd     .,		/*
		*/ label("Model:")
  VARLIST  vl_terms     @         _ss       _iwd      .,                /*
		*/ label("Model")

  GROUPBOX gb_modvars   @         _ls       _iwd      _ht11,		/*
		*/ label("Model variables")
  DEFINE   holdy @y
  RADIO    rb_allcat    _indent   _ss       _inwd     ., first		/*
		*/ clickon("script allcat")				/*
		*/ label("All categorical")
  RADIO    rb_cont      @         _ss       @         .,		/*
		*/ clickon("script cont")				/*
	     */ label("Categorical except the following continuous variables:")
  VARLIST  vl_cont      @         _ss       @         .,		/*
		*/ option(continuous)					/*
	     */ label("Categorical except the following continuous variables")
  /* -class()- not included since it is a synonym for -category()- */
  RADIO    rb_category  @         _ms       @         ., last		/*
		*/ clickon("script category")				/*
	     */ label("Continuous except the following categorical variables:")
  VARLIST  vl_category  @         _ss       @         .,		/*
		*/ option(category)					/*
	     */ label("Continuous except the following categorical variables")

  CHECKBOX ck_noconst   _lft      _xxls     _iwd      .,		/*
		*/ option(noconstant)					/*
		*/ label("Suppress constant term")

END


INCLUDE byifin
INCLUDE weights_fa

DIALOG rpt, tabtitle("Reporting")
BEGIN
  CHECKBOX ck_detail    _lft      20        _iwd      .,		/*
		*/ option(detail)					/*
		*/ label("Report categorical variable value mappings")
END

SCRIPT examples
BEGIN
	view help anova_example##|_new
END

SCRIPT allcat
BEGIN
	main.vl_cont.disable
	main.vl_category.disable
END

SCRIPT cont
BEGIN
	main.vl_cont.enable
	main.vl_category.disable
END

SCRIPT category
BEGIN
	main.vl_cont.disable
	main.vl_category.enable
END


PROGRAM command
BEGIN
	INCLUDE _by_pr
	put "manova "
	varlist main.vl_dv
	put " = "
	varlist main.vl_terms
	INCLUDE _weights_pr
	INCLUDE _ifin_pr
	beginoptions
		if main.rb_cont {
			require main.vl_cont
			optionarg main.vl_cont
		}
		if main.rb_category {
			require main.vl_category
			optionarg main.vl_category
		}
		option main.ck_noconst
		option rpt.ck_detail
	endoptions
END