manovatest.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
	manovatest	(for use after manova)

	VERSION 1.0.1  31mar2005
*/
VERSION 8.0

INCLUDE _std_medium
INCLUDE _ht310
INCLUDE header

HELP hlp1, view("help manovatest")
RESET res1

DIALOG main, label("manovatest - multivariate tests after manova") /*
		*/ tabtitle("Main")
BEGIN
  GROUPBOX gb_type        _lft      _top       _iwd     _ht6,		/*
		*/ label("Test type:")
  RADIO    rb_terms       _ilft     _ss        _inwd    ., first	/*
		*/ clickon(program terms_on)				/*
		*/ label("Test effects (terms from the manova)")
  RADIO    rb_test	  @         _ss        @        .,		/*
		*/ clickon(program test_on)				/*
		*/ label("Test based on linear combinations of design matrix")
  RADIO    rb_showorder   @         _ss        @        ., last		/*
		*/ clickon(program all_off)				/*
		*/ label("Show definition of each column of the design matrix")
  BUTTON   bu_termsexamp  _lft4_4   _xls       _cwd4_1  .,		/*
		*/ push("script examples")                              /*
		*/ label("Examples...")
  DEFINE   holdy @y
  TEXT     tx_terms       _lft      +5         _comb4_1 .,		/*
		*/ label("Effects (terms) to test:")
  VARLIST  vl_terms       @         _ss        _iwd     .,		/*
		*/ label("Effects (terms) to test")
  TEXT     tx_test        _lft      holdy      _iwd     .,		/*
	*/ label("Matrix containing linear combinations of design matrix:")
  LISTBOX  lb_test        @         _ss        @        _ht4,		/*
		*/ contents(matrix)					/*
		*/ option(test)						/*
	*/ label("Matrix containing linear combinations of design matrix")
  CHECKBOX ck_ytrans      @         _vs4       @        .,		/*
		*/ clickon("gaction main.lb_ytrans.enable")		/*
		*/ clickoff("gaction main.lb_ytrans.disable")		/*
	*/ label("Apply transformation of dependent variables based on matrix:")
  LISTBOX  lb_ytrans      @         _ss        @        _ht4,		/*
		*/ contents(matrix)					/*
		*/ option(ytransform)					/*
	*/ label("Apply transformation of dependent variables based on matrix")
END

PROGRAM all_off
BEGIN
	call gaction main.tx_terms.hide
	call gaction main.vl_terms.hide
	call gaction main.bu_termsexamp.hide
	call gaction main.tx_test.hide
	call gaction main.lb_test.hide
	call gaction main.ck_ytrans.hide
	call gaction main.lb_ytrans.hide
END

PROGRAM terms_on
BEGIN
	call program all_off
	call gaction main.tx_terms.show
	call gaction main.vl_terms.show
	call gaction main.bu_termsexamp.show
	call gaction main.ck_ytrans.show
	call gaction main.lb_ytrans.show
END

PROGRAM test_on
BEGIN
	call program all_off
	call gaction main.tx_test.show
	call gaction main.lb_test.show
	call gaction main.ck_ytrans.show
	call gaction main.lb_ytrans.show
END


SCRIPT examples
BEGIN
	view help anova_example##|_new
END


PROGRAM command
BEGIN
	put "manovatest "
	if main.rb_terms {
		varlist main.vl_terms
	}
	beginoptions
		if main.rb_showorder {
			put "showorder"
		}
		if main.rb_terms {
			if main.ck_ytrans {
				require main.lb_ytrans
				optionarg main.lb_ytrans
			}
		}
		if main.rb_test {
			require main.lb_test
			optionarg main.lb_test
			if main.ck_ytrans {
				require main.lb_ytrans
				optionarg main.lb_ytrans
			}
		}
	endoptions
END