mkspline.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  mkspline

*! VERSION 1.0.1  26aug2003

*/

VERSION 8.0

INCLUDE _std_large
INCLUDE _ht280
INCLUDE header

HELP hlp1, view("help mkspline")
RESET res1

DIALOG main, label("mkspline - Linear spline construction") /*
		*/ tabtitle("Main")
BEGIN
  /*--+----1----+----2----+----3----+----4----+----5----+----6----+----7----+*/
  TEXT      tx_oldvar       _lft       _top      _iwd      .,           /*
 		 */label("Make spline of variable:")
  VARNAME   vn_oldvar       @          _ss       _vnwd     .,		/*
  		*/label("Make spline of variable")
  GROUPBOX  gb_spl          @          _ls       _iwd      _ht18,	/*
  		*/label("Create spline by specifying")
  RADIO     rb_var          _indent    _ss       _ibwd     .,		/*
  		*/label("New variables and knots:")			/*
  		*/clickon("script var_on") first
  DEFINE holdx @x
  EDIT      ed_var          _indent2   _ss       _inwd     .,		/*
  		*/label("New variables and knots")
  EDIT      ed_var2         @          _ms       @         .,		/*
  		*/label("New variables and knots")
  EDIT      ed_var3         @          _ms       @         .,		/*
  		*/label("New variables and knots")
  TEXT      tx_var          @          _ss       _inwd     .,		/*
		*/label(`"Example: "mild 10 moderate 20 heavy 30 extreme""')
  TEXT      tx_var2         @          _vss      @         .,		/*
	*/label("Note: the last new variable is not followed by a knot")
  RADIO     rb_stub         holdx      _ls       _ibwd     .,		/*
  		*/label("New variable stub and number of knots:")	/*
  		*/clickon("script stub_on") last
  EDIT      ed_stub         _indent2   _ss       _en14wd   .,		/*
		*/max(31)						/*
  		*/label("New variable stub")
  SPINNER   sp_stub         _en14sep   @         _spwd     .,		/*
  		*/min(2) max(1000000000) default(2)			/*
  		*/label("Number of knots")
END

INCLUDE ifin

DIALOG opt, label("") /*
		*/ tabtitle("Options")
BEGIN
  /*--+----1----+----2----+----3----+----4----+----5----+----6----+----7----+*/
  GROUPBOX  gb_marg        _lft      _top      _iwd      _ht4,         /*
*/label("Construct new variables so that when they are used in estimation")
  RADIO     rb_nomarg      _indent   _ss       _inwd     .,		/*
*/label("Coefficients measure the slopes for the intervals")		/*
  		*/option("NONE") first
  RADIO     rb_marg        @         _ss       @         .,		/*
*/label("Coefficients represent the change in slope from the preceding interval")/*
  		*/option(marginal) last
  CHECKBOX  ck_pctile      _lft      _xls      _iwd      .,		/*
*/label("Place knots at percentiles rather than equally spaced over the range")/*
  		*/option("pctile")
END

SCRIPT var_on
BEGIN
  main.ed_var.enable
  main.ed_var2.enable
  main.ed_var3.enable
  main.tx_var.enable
  main.tx_var2.enable
  main.ed_stub.disable
  main.sp_stub.disable
  opt.ck_pctile.disable
END

SCRIPT stub_on
BEGIN
  main.ed_var.disable
  main.ed_var2.disable
  main.ed_var3.disable
  main.tx_var.disable
  main.tx_var2.disable
  main.ed_stub.enable
  main.sp_stub.enable
  opt.ck_pctile.enable
END

PROGRAM command
BEGIN
	put "mkspline "
	if main.rb_var{
		if !(main.ed_var | main.ed_var2 | main.ed_var3) {
			require main.ed_var
		}
		put main.ed_var
		put " "
		put main.ed_var2
		put " "
		put main.ed_var3
	}
	if main.rb_stub{
		require main.ed_stub
		put main.ed_stub " "
		put main.sp_stub " "
	}
	put "="
	varlist main.vn_oldvar
	INCLUDE _ifin_pr
	beginoptions
		option radio(opt rb_nomarg rb_marg)
		if main.rb_stub{
			option opt.ck_pctile
		}
	endoptions
END