max_internal.idlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
    max_internal.idlg

*!  VERSION 1.1.5  31mar2005

    // SCRIPTS and PROGRAMS for external use
	* SCRIPT max_setDefaultNoLog
	* SCRIPT max_setLTolNotAllowed
	* SCRIPT max_sample_weight_off
	* SCRIPT max_disable
	* SCRIPT max_enable
	* PROGRAM max_output

*/

DIALOG max, tabtitle("Max options")
BEGIN
  BUTTON   bu_hlp    _xsetbu	_top     _setbuwd  .,		///
	label("Maximize Help")					///
	onpush(script max_hlp)

  SPINNER  sp_iter   _lft       _top     _spwd     .,		///
	label("Maximum iterations")				///
	min(0) max(16000) default(c(maxiter))			///
	option(iterate)
  TEXT     tx_iter   _spsep    @         _spr2b    .,		///
	label("Maximum iterations")

  GROUPBOX gb_log    _lft      _ls       _cwd1     _ht6,	///
	label("Iteration log")
  DEFINE holdy @y
  DEFINE cx @cx
  DEFINE cy @cy

  RADIO	   rb_log    _indent  _ss       _inwd	   .,		///
	label("Show log") first option(NONE)
  RADIO    rb_trace  @         _ss       @         .,		///
	label("Show log and parameter vector")			///
	option(trace)
  RADIO	   rb_nolog  @         _ss       @	   .,		///
	label("Suppress log") last option(nolog)

  // These are copies that are used when the default is nolog
  RADIO	   rb_nolog2 @         -40       @         .,		///
	label("Suppress log") first option(NONE)
  RADIO    rb_trace2 @         _ss       @         .,		///
	label("Show log and parameter vector")			///
	option(trace)
  RADIO	   rb_log2   @         _ss       @	   .,		///
	label("Show log") last option(log)

  GROUPBOX gb_tol    _lft2     holdy     cx        cy,		///
	label("Convergence tolerances")

  EDIT     ed_tol    _ilft2    _ms       _en7wd    .,		///
	label("Coefficient vector")				///
	option(tolerance) default(1e-4)
  TEXT     tx_tol    _en7sep   @         _en7r2b   .,		///
	label("Coefficient vector")

  EDIT     ed_ltol   _ilft2    _ls       _en7wd    .,		///
	label("Log likelihood")					///
	option(ltolerance) default(0)
  TEXT     tx_ltol   _en7sep   @         _en7r2b   .,		///
	label("Log likelihood")
END

SCRIPT max_PREINIT
BEGIN
	create BOOLEAN max_isNoLTol

	// These must be already be hidden when they are created
	//	so they are tested properly the first time.
	max.rb_nolog2.hide
	max.rb_trace2.hide
	max.rb_log2.hide
END

PROGRAM disable_max
BEGIN
	call max.sp_iter.disable
	call max.tx_iter.disable
	call max.gb_log.disable
	call max.rb_nolog.disable
	call max.rb_log.disable
	call max.rb_nolog2.disable
	call max.rb_trace2.disable
	call max.rb_log2.disable
	call max.rb_trace.disable
	call max.gb_tol.disable
	call max.ed_tol.disable
	call max.tx_tol.disable
	call max.ed_ltol.disable
	call max.tx_ltol.disable
END

PROGRAM enable_max
BEGIN
	call max.sp_iter.enable
	call max.tx_iter.enable
	call max.gb_log.enable
	call max.rb_nolog.enable
	call max.rb_log.enable
	call max.rb_trace.enable
	call max.rb_log2.enable
	call max.rb_nolog2.enable
	call max.rb_trace2.enable
	call max.gb_tol.enable
	call max.ed_tol.enable
	call max.tx_tol.enable
	if ! max_isNoLTol {
		call max.ed_ltol.enable
		call max.tx_ltol.enable
	}
END

SCRIPT max_hlp
BEGIN
	view help maximize##|_new
END

/*******  Scripts for external use  *******/
SCRIPT max_setDefaultNoLog
BEGIN
	max.rb_log.hide
	max.rb_trace.hide
	max.rb_nolog.hide
	max.rb_log2.show
	max.rb_trace2.show
	max.rb_nolog2.show

END

SCRIPT max_setLTolNotAllowed
BEGIN
	max_isNoLTol.settrue
	max.ed_ltol.hide
	max.tx_ltol.hide
	max.bu_hlp.hide
	max.settabtitle "Opt options"
	max.ed_tol.setvalue "1e-6"
	max.ed_tol.setdefault "1e-6"
END

SCRIPT max_sample_weight_off
BEGIN
	script se_setDefaultOtherWeight
END

SCRIPT max_enable
BEGIN	// wrapper for a program
	program enable_max
END

SCRIPT max_disable
BEGIN	// wrapper for a program
	program disable_max
END

PROGRAM max_output
BEGIN
	option max.rb_log
	option max.rb_trace
	option max.rb_nolog
	option max.rb_log2
	option max.rb_nolog2
	option max.rb_trace2
	optionarg /hidedefault max.sp_iter
	optionarg /hidedefault max.ed_tol
	optionarg /hidedefault max.ed_ltol
END