logit.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  logit

*! VERSION 1.1.2  15mar2005

  keyword:  eclass

*/

VERSION 9.0

INCLUDE _std_large
INCLUDE header

HELP hlp1, view("help logit")
RESET res1

DIALOG main, label("logit - Logistic regression, reporting coefficients")	/*
		*/ tabtitle("Model")
BEGIN
  INCLUDE _dviv

  CHECKBOX ck_nocons @         _ms       @         .,			/*
  		*/ label("Suppress constant term")			/*
  		*/ option("noconstant")					/*
		*/

  GROUPBOX gb_output _lft      _xls      _iwd      _ht8,		/*
		*/ label("Options")					/*
		*/

  TEXT     tx_offset _ilft     _ms       _cwd2     .,			/*
		*/ label("Offset variable:")				/*
		*/
  VARNAME  vn_offset @         _ss       _vnwd     .,			/*
		*/ label("Offset variable")				/*
		*/ option("offset")					/*
		*/

  CHECKBOX ck_asis   @         _ls       _ibwd     .,			/*
		*/ label("Retain perfect predictor variables")		/*
		*/ option("asis")					/*
		*/
END

INCLUDE byifin
INCLUDE weights_fpi
INCLUDE se

SCRIPT PREINIT
BEGIN
	script se_createAsInternalML
END

DIALOG rpt, tabtitle("Reporting")
BEGIN
  DEFINE _x _lft
  DEFINE _cx _spr
  DEFINE _y _top
  INCLUDE _sp_level

  RADIO    rb_default _lft     _ls       _cwd1     .,			/*
  		*/ label("Report coefficients (default)") first
  RADIO    rb_or      @        _ss       @         .,			/*
  		*/ label("Report odds ratios")				/*
  		*/ option(or) last
END

PROGRAM rpt_output
BEGIN
	optionarg /hidedefault rpt.sp_level
	option rpt.rb_or
END

INCLUDE max_internal

PROGRAM command
BEGIN
	allowxi
	INCLUDE _by_pr
	put "logit "
	varlist main.vn_dv [main.vl_iv]
	if !main.vl_iv & main.ck_nocons {
	  stopbox stop `""Suppress constant term" is selected without independent variables."'
	}
	INCLUDE _weights_pr
	INCLUDE _ifin_pr
	beginoptions
		option main.ck_nocons
		optionarg main.vn_offset
		option main.ck_asis
		put " " /program se_output
		put " " /program rpt_output
		put " " /program max_output
	endoptions
END