logit.ado

来自「是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到」· ADO 代码 · 共 44 行

*! version 1.0.9  24feb2005
program define logit, eclass sortpreserve byable(onecall) ///
		prop(or svyb svyj svyr swml)
	version 9, missing
	local version : di "version " string(_caller()) ", missing :"

	if _by() {
		local BY `"by `_byvars'`_byrc0':"'
	}
	`version' `BY' _vce_parserun logit : `0'
	if "`s(exit)'" != "" {
		exit
	}
	if replay() {
		if !inlist("`e(cmd)'", "logit", "blogit", "logistic") {
			error 301
		}
		if _by() {
			error 190
		}
		`version' Display `0'
		exit
	}
	syntax [anything] [if] [in] [fw iw pw aw] [, * ]
	`version' `BY' _logit `0'
	ereturn local title "Logistic regression"
end

program Display
	version 9
	local version : di "version " string(_caller()) ":"
	// NOTE: option -alttitle- ignored on purpose
	syntax [, Level(cilevel) GROUPED alttitle * ]
	if "`e(prefix)'" != "" {
		_coef_table_header
		di
		_coef_table, level(`level') `options'
		_prefix_footnote
	}
	else	`version' _logit, level(`level') `grouped' `options'
end

exit