label_values.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
	label values

*!  VERSION 1.1.0  28mar2005

	which label - built-in command:  label
*/

VERSION 9.0

INCLUDE _std_medium
INCLUDE header

HELP hlp1, view("help label")
RESET res1

DIALOG main, label("label values - Attach value label") tabtitle("Main")
BEGIN
  GROUPBOX gb_action _lft      _top      _iwd      _ht4,	///
  	label("Add or remove value label")
  RADIO    rb_attach _ilft     _ss       _inwd     .,		///
	label("Attach a value label to a variable")		///
	first onclickon(script main_new_on)
  RADIO    rb_remove @         _ss       @         .,		///
	label("Remove a value label from a variable") last 	///
	onclickon(script main_new_off)

  TEXT     tx_var    _lft      +45      _cwd1     .,		///
	label("Variable:")
  TEXT     tx_label  _lft2     @         @         .,		///
  	label("Value label:")
  VARNAME  vn_var    _lft      _ss       _vnwd     .,		///
	label("Variable")

  COMBOBOX lb_label  _lft2     @         _vnwd     _ht4,	///
	contents(valuelabels) label("Value label") dropdownlist

  CHECKBOX ck_nofix  _lft      _xls       _iwd      .,		///
	option(nofix) label("Do not automatically widen display formats")
END

SCRIPT main_new_on
BEGIN
	main.tx_label.show
	main.lb_label.show
	main.ck_nofix.show
END

SCRIPT main_new_off
BEGIN
	main.tx_label.hide
	main.lb_label.hide
	main.ck_nofix.hide
END

PROGRAM command
BEGIN
	put "label values "
	varlist main.vn_var
	if main.rb_attach {
		put main.lb_label
	}
	beginoptions
		if main.rb_attach {
			option main.ck_nofix
		}
	endoptions
END