line_g.class

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*                                 line_g

	a view of a line

        This is a subview.  When drawn, assumes that the appropriate x and y
        scales have already been set.

*/
*! version 1.0.0  30jul2002

version 8

class {
	double x0
	double y0
	double x1
	double y1

	class linestyle style
} , inherit(subview)


/*--------------------------------------------------------------------------*/
/*
	Usage:  .line_g.new x0 y0 x1 y1 [ , style(stylename) styleref(name|key)]

	if reference is specified the style is assigned by reference rather
	than by copying (by value)
*/

program define new

	syntax anything(name=poslist id="4 position numbers") [ , 	/*
		*/ Style(passthru) STYLEREF(passthru) * ]

	numlist "`poslist'" , min(4) max(4)
	local poslist `r(numlist)'
	foreach d in x0 y0 x1 y1 {
		gettoken `d' poslist : poslist , parse(" ,")
		.`d' = ``d''
	}

	if "`style'" == "" & "`styleref'" == "" {
		local style style(scheme)
	}

	.setstyle , `style' `styleref' `options'

end


/*--------------------------------------------------------------------------*/

program define draw

	.style.setgdifull

	gdi line `.x0' `.y0' `.x1' `.y1'
end