logistic.ado

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

*! version 3.2.8  22mar2005
program define logistic, prop(or svyb svyj svyr swml) byable(onecall)
	version 6.0, missing
	local version : di "version " string(_caller()) ", missing :"

	if _by() {
		local BY `"by `_byvars'`_byrc0':"'
	}
	`version' `BY' _vce_parserun logistic : `0'
	if "`s(exit)'" != "" {
		exit
	}
        if replay() {
		if `"`e(cmd)'"'~=`"logistic"' { error 301 }
		if _by() { error 190 }
		Display `0'
		exit
	}
	quietly syntax [anything] [if] [in] [fw iw pw aw] [, * ]
	`version' `BY' Estimate `0'
end

program Estimate, eclass byable(recall)
	version 6.0, missing
	syntax varlist(ts) [fweight pweight iweight] [if] [in] /*
		*/ [, Level(cilevel) COEF log SCore(passthru) /*
		*/ VCE(passthru) *]
	if _by() {
		_byoptnotallowed score() `"`score'"'
	}

	tempvar touse 
	mark `touse' `if' `in'
	cap noi qui logit `varlist' if `touse' [`weight'`exp'], /*
	*/	`score' `options' nolog alttitle
	if _rc { 
		if _rc!=2000 & _rc!=2001 { exit _rc } 
		local rc = _rc
		cap noi logit `varlist' if `touse' [`weight'`exp'], /*
			*/	`options' nocoef nolog alttitle
		exit `rc'
	}
	capture global S_E_vl = _b[_cons]
	if _rc { 
		di in red `"may not drop constant"'
		exit 399
	}
	/* we pick up other e() things from -logit- */
	est local wtype		`"`weight'"'
	est local wexp		`"`exp'"'
	est local predict	`"logistic_p"'

	if (1) {   /* double save in S_E_  */
		global S_E_vl   `"`varlist'"'
		global S_E_if   `"`if'"'
		global S_E_in   `"`in'"'
		global S_E_wgt  `"`weight'"'
		global S_E_exp  `"`exp'"'
		global S_E_ll   `"`e(ll)'"'
		global S_E_nobs `"`e(N)'"'
		global S_E_mdf  `"`e(df_m)'"'
		global S_E_cmd  "logistic"
	}
	est local cmd "logistic"

	Display, level(`level') `coef'
end

program Display
	version 9
	syntax [, Level(cilevel) COEF ]
	if `"`coef'"'=="" {
		logit, or level(`level') alttitle
	}
	else	logit, level(`level') alttitle
end
exit