svy_logistic.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  svy: logistic

*!  VERSION 1.1.2  15mar2005

  keyword:  eclass

*/

VERSION 9.0

INCLUDE _std_large
INCLUDE _ht330
INCLUDE header

HELP hlp1, view("help svy: logistic")
RESET res1

DIALOG main, tabtitle("Model") ///
label("svy: logistic - Logistic regression, reporting odds ratios, for survey data")
BEGIN
  INCLUDE _dviv

  CHECKBOX ck_nocons	@	_ms	@	.,		///
	label("Suppress constant term")				///
	option(noconstant)

  GROUPBOX gb_output	_lft	_xls	_iwd	_ht8,		///
	label("Options")

  TEXT     tx_offset	_ilft	_ms	_ibwd	.,		///
	label("Offset variable:")
  VARNAME  vn_offset	@	_ss	_vnwd	.,		///
	label("Offset variable")				///
	option(offset)

  CHECKBOX ck_asis	@	_ls	_cwd1	.,		///
	label("Retain perfect predictor variables")		///
	option(asis)

  DEFINE _x _xsetbu
  DEFINE _y 300
  INCLUDE _bu_svyset

END

INCLUDE svy_subpop_model
INCLUDE svy_se
INCLUDE svy_rpt
INCLUDE max_internal

SCRIPT POSTINIT
BEGIN
	script svy_rpt_setViewAsLogistic
	script max_setDefaultNoLog
END

PROGRAM svy_options
BEGIN
	beginoptions
		put " " /program svy_subpop_output
		put " " /program svy_se_output
		put " " /program svy_rpt_output
	endoptions
END

PROGRAM command
BEGIN
	allowxi
	put "svy"
	put /program svy_options
	put ": logistic "
	varlist main.vn_dv [main.vl_iv]
	if !main.vl_iv & main.ck_nocons {
		stopbox stop ///
`""Suppress constant term" is selected without independent variables."'
	}
	if subpop.ck_ifin {
		put " " /program ifin_output
	}
	beginoptions
		option main.ck_nocons
		optionarg main.vn_offset
		option main.ck_asis
		put " " /program svy_rpt_cmdoutput
		put " " /program max_output
	endoptions
END