stset.ado

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

*! version 6.0.2  15sep2004
/*
	stset
	stset, [no]show
	stset, clear

	stset time cat[, options]
*/

program define stset, sort
	version 6, missing

	if _caller()<6 {
		ztset_5 `0'
		exit
	}

	if replay() {					/* sic */
		st_is 2 full
		if `"`0'"' == "" { 
			streset
			exit
		}
		syntax [, CLEAR Show]
		if "`clear'" != "" {
			st_set clear
			exit
		}
		if "`show'"!="" {
			char _dta[st_show] 
		}
		else	char _dta[st_show] "noshow"
		exit
	}

	syntax varlist(numeric max=2) [if/] [fw pw iw/] [, /*
		*/ AFTER(string)	/*
		*/ BEFORe(string)	/*
		*/ ENter(string) ENTRy(string) 	/*
		*/ EXit(string)		/*
		*/ EVER(string)		/*
		*/ Failure(string)	/*
		*/ ID(varname) 		/*
		*/ IFopt(string)	/*
		*/ NEVER(string)	/*
		*/ Origin(string)	/*
		*/ SCale(real 1)	/*
		*/ noShow		/*
		*/ TIME0(string) ]


	tokenize `varlist'
	if "`2'"!="" {
		if `"`failure'"' != "" {
			di in red "may not mix old and new syntax"
			di in red "may not specify two variables and failure()"
			exit 198
		}
		local failure "`2'"
	}

	if `"`entry'"' != "" { 
		if `"`enter'"'!="" {
			error 198
		}
		local enter `"`entry'"'
	}

	st_set 	set "nocmd" /*
		         id    bt     bt0       fail        bs
		*/ 	"`id'" "`1'" `"`time0'"' "`failure'"  `scale'	/*

			     		enter		exit
		*/	           	`"`enter'"'	`"`exit'"'	/*

			origin
		*/	`"`origin'"'					/*

			ifexp		if		ever
		*/	`"`if'"'	`"`ifopt'"'	`"`ever'"'	/*

			never		after		before
		*/	`"`never'"'	`"`after'"'	`"`before'"'	/*

			wt		wv		show
		*/	"`weight'"	`"`exp'"'	"`show'"

end