svy_se.idlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  svy_se.idlg -- standard include dialog for -svy, vce()- options

*! VERSION 1.0.5  25mar2005

	// SCRIPTS and PROGRAMS for external use

		* SCRIPT svy_se_IS_SVYSET
		* PROGRAM svy_se_output
*/

DIALOG svy_se, tabtitle("SE")
BEGIN
  // NOTE: This EDIT control is used to activate the currently svyset -mse-
  // option. It should be invisible.
  EDIT     ed_mse 0 0 0 0, default(char _dta[_svy_mse])

  TEXT     tx_vce	_lft	_top	_iwd	.,		///
	label("Method for variance estimation:")
  LISTBOX  lb_vce	@	_ss	225	55,		///
  	default(char _dta[_svy_vce])				///
	contents(svy_se_contents)				///
	values(svy_se_values)					///
	onselchangelist(svy_se_change)				///
	option(vce) nomem
DEFINE holdy @y

  TEXT     tx_hadamard	_lft	+65	_vnwd	.,		///
	label("Hadamard matrix:")
  EDIT     ed_hadamard	@	_ss	@    	.,		///
	label("Hadamard matrix")				///
	option(hadamard)
  TEXT     tx_fay	@	_ls	_vnwd	.,		///
	label("Fay's adjustment:")
  EDIT     ed_fay	@	_ss	@    	.,		///
  	numonly							///
	label("Fay's adjustment")				///
	option(fay)

  CHECKBOX ck_mse	_lft2	holdy	_cwd1	.,		///
	label("Use MSE formula") option(mse)
  CHECKBOX ck_nodots	@	_ms	@	.,		///
	label("Suppress the replication dots") option(nodots)
END

SCRIPT svy_se_clear
BEGIN
	svy_se.ed_mse.setvalue ""
	script svy_se_linearized
	svy_se.lb_vce.setvalue "linearized"
	svy_se.ck_mse.setoff
	svy_se.ck_nodots.setoff
	svy_se.ed_hadamard.setvalue ""
	svy_se.ed_fay.setvalue ""
END

SCRIPT svy_se_PREINIT
BEGIN
	create BOOLEAN is_svyset
	svy_se.ck_mse.hide
	svy_se.ck_nodots.hide
	svy_se.tx_hadamard.hide
	svy_se.ed_hadamard.hide
	svy_se.tx_fay.hide
	svy_se.ed_fay.hide
END

SCRIPT svy_se_POSTINIT
BEGIN
	svy_se.ed_mse.hide
	program svy_se_check_mse
END

PROGRAM svy_se_check_mse
BEGIN
	if svy_se.ed_mse.equals("mse") {
		call svy_se.ck_mse.seton
	}
END

SCRIPT svy_se_IS_SVYSET
BEGIN
	is_svyset.settrue
	svy_se.lb_vce.withvalue svy_se.lb_vce.setvalue "@"
END

LIST svy_se_contents
BEGIN
	Linearized
	BRR
	Jackknife
END

LIST svy_se_values
BEGIN
	linearized
	brr
	jackknife
END

LIST svy_se_change
BEGIN
	script svy_se_linearized
	program svy_se_brr
	program svy_se_jackknife
END

SCRIPT svy_se_linearized
BEGIN
	svy_se.tx_vce.setlabel "Method for variance estimation: (Linearized)"
	svy_se.ck_mse.hide
	svy_se.ck_nodots.hide
	svy_se.tx_hadamard.hide
	svy_se.ed_hadamard.hide
	svy_se.tx_fay.hide
	svy_se.ed_fay.hide
END

PROGRAM svy_se_brr
BEGIN
	call svy_se.tx_vce.setlabel "Method for variance estimation: (BRR)"
	call svy_se.ck_mse.show
	if !is_svyset {
		call svy_se.ck_nodots.show
		call svy_se.tx_hadamard.show
		call svy_se.ed_hadamard.show
		call svy_se.tx_fay.show
		call svy_se.ed_fay.show
	}
	if is_svyset {
		call svy_se.ck_nodots.hide
		call svy_se.tx_hadamard.hide
		call svy_se.ed_hadamard.hide
		call svy_se.tx_fay.hide
		call svy_se.ed_fay.hide
	}
END

PROGRAM svy_se_jackknife
BEGIN
	call svy_se.tx_vce.setlabel ///
		"Method for variance estimation: (Jackknife)"
	call svy_se.ck_mse.show
	if !is_svyset {
		call svy_se.ck_nodots.show
		call svy_se.tx_hadamard.hide
		call svy_se.ed_hadamard.hide
		call svy_se.tx_fay.hide
		call svy_se.ed_fay.hide
	}
	if is_svyset {
		call svy_se.ck_nodots.hide
		call svy_se.tx_hadamard.hide
		call svy_se.ed_hadamard.hide
		call svy_se.tx_fay.hide
		call svy_se.ed_fay.hide
	}
END

PROGRAM svy_se_output
BEGIN
	optionarg svy_se.lb_vce
	option svy_se.ck_mse
	option svy_se.ck_nodots
	optionarg svy_se.ed_hadamard
	optionarg svy_se.ed_fay
END