svy_mlogit_p.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
	predict (after svy: mlogit)

*!  VERSION 1.0.2  31mar2005

*/

VERSION 9.0

INCLUDE _std_large
INCLUDE _ht260
INCLUDE header

HELP hlp1, view("help svy: mlogit postestimation")
RESET res1


DIALOG main, label("predict - Prediction after estimation") tabtitle("Main")
BEGIN
  TEXT     tx_vars           _lft      _top      _comb4_1  .,		/*
		*/ label("New variable names or variable stub* :")
  EDIT     ed_vars           @         _ss       @         .,		/*
		*/ label("New variable names or variable stub* :")
  TEXT     tx_var            _lft      _top      @         .,		/*
		*/ label("New variable name:")
  EDIT     ed_var            @         _ss       _vnwd     .,		/*
		*/ label("New variable name") max(32)

  TEXT     tx_type           _lft4_4   _top      _cwd4_1   .,		/*
		*/ label("As type:")
  COMBOBOX cb_type           @         _ss       @         .,		/*
		*/ dropdownlist						/*
		*/ contents("type")					/*
		*/ label("Type")

  GROUPBOX gb_opts           _lft      _ls       _iwd      _ht16,	/*
		*/ label("Produce:")
  RADIO    rb_p_all          _ilft     _ss       _inwd     ., first	/*
		*/ option(p)						/*
		*/ clickon("script manyon")				/*
    */ label("Probabilities (specify as many variables as number of outcomes)")
  RADIO    rb_score          _ilft     _ss       _comb3_2  .,		/*
		*/ option(scores)					/*
		*/ clickon("script offboth")				/*
		*/ label("Equation-level scores")
  DEFINE   holdy@y
  RADIO    rb_p              _ilft     _ss       _comb3_2  .,		/*
		*/ option(p)						/*
		*/ clickon("script oneon")				/*
		*/ label("Probability (specify one variable)")
  RADIO    rb_xb             @         _ss       @         .,		/*
		*/ option(xb)						/*
		*/ clickon("script oneon")				/*
		*/ label("Linear prediction (xb)")
  RADIO    rb_stdp           @         _ss       @         ., last	/*
		*/ option(stdp)						/*
		*/ clickon("script oneon")				/*
		*/ label("Standard error of linear prediction")

  TEXT     tx_outcome        _ilft3_3  holdy     _cwd3_2   .,		/*
		*/ label("Outcome:")
  LISTBOX  lb_outcome        @         _ss       @         _ht8h,	/*
		*/ option(outcome)					/*
		*/ contents(ereturn eqnames)				/*
		*/ label("Outcome")
END


INCLUDE ifin
INCLUDE _type_list_fd

SCRIPT offboth
BEGIN
	script manyvars
	script eqoff
END

SCRIPT manyon
BEGIN
	script manyvars
	script eqoff
END

SCRIPT oneon
BEGIN
	script onevar
	script eqon
END

SCRIPT manyvars
BEGIN
	main.tx_vars.show
	main.ed_vars.show
	main.tx_var.hide
	main.ed_var.hide
END

SCRIPT onevar
BEGIN
	main.tx_vars.hide
	main.ed_vars.hide
	main.tx_var.show
	main.ed_var.show
END

SCRIPT eqon
BEGIN
	main.tx_outcome.enable
	main.lb_outcome.enable
END

SCRIPT eqoff
BEGIN
	main.tx_outcome.disable
	main.lb_outcome.disable
END


PROGRAM command
BEGIN
	put "predict "
	put main.cb_type " "
	if main.rb_p_all | main.rb_score {
		require main.ed_vars
		put main.ed_vars " "
	}
	if !main.rb_p_all {
		require main.ed_var
		put main.ed_var " "
	}
	INCLUDE _ifin_pr
	beginoptions
		if !main.rb_p_all {
			require main.lb_outcome
			optionarg main.lb_outcome
		}
		option radio(main rb_p_all rb_score rb_p rb_xb rb_stdp)
	endoptions
END