sureg.hlp

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

{smcl}
{* 21mar2005}{...}
{cmd:help sureg}{right:dialog:  {bf:{dialog sureg}}{space 15}}
{right:also see:  {help sureg postestimation}}
{hline}

{title:Title}

{synoptset 11}{...}
{synopt:{hi:[R] sureg} {hline 2}}Zellner's seemingly unrelated regression{p_end}
{p2colreset}{...}


{title:Syntax}

{pstd}
Basic syntax

{p 8 14 2}
{cmd:sureg}
{cmd:(}{it:{help depvar:depvar1}} {it:{help varlist:varlist1}}{cmd:)}
{cmd:(}{it:depvar2 varlist2}{cmd:)}
{it:...}
{cmd:(}{it:depvarN varlistN}{cmd:)}
{ifin}
{weight}

{pstd}
Full syntax

{p 8 14 2}
{cmd:sureg}
{cmd:(}[{it:eqname1}{cmd::}]
{it:{help depvar:depvar1a}} [{it:depvar1b ...} {cmd:=}]
{it:{help varlist:varlist1}} [{cmd:,} {opt noc:onstant}]{cmd:)}{p_end}
{p 14 14 2}
{cmd:(}[{it:eqname2}{cmd::}] {it:depvar2a} [{it:depvar2b ...} {cmd:=}]
{it:varlist2} [{cmd:,} {opt noc:onstant}]{cmd:)}{p_end}
{p 14}{it:...}{p_end}
{p 14 14 2}
{cmd:(}[{it:eqnameN}{cmd::}] {it:depvarNa} [{it:depvarNb ...} {cmd:=}]
{it:varlistN} [{cmd:,} {opt noc:onstant}]{cmd:)}
     {ifin} {weight} [{cmd:,} {it:options}]

{pstd}
Explicit equation naming ({it:eqname}{cmd::}) cannot be combined with multiple
dependent variables in an equation specification.

{synoptset 26 tabbed}{...}
{synopthdr}
{synoptline}
{syntab:Model}
{synopt:{opt i:sure}}iterate until estimates converge{p_end}
{synopt:{cmdab:c:onstraints(}{it:{help estimation options##constraints():constraints}}{cmd:)}}apply specified linear constraints{p_end}

{syntab:df adj.}
{synopt:{opt sm:all}}report small-sample statistics{p_end}
{synopt:{opt dfk}}use small-sample adjustment{p_end}
{synopt:{opt dfk2}}use alternate adjustment{p_end}

{syntab:Reporting}
{synopt:{opt l:evel(#)}}set confidence level; default is {cmd:level(95)}{p_end}
{synopt:{opt cor:r}}perform Breusch-Pagan test{p_end}

{syntab:Opt options}
{synopt :{it:{help sureg##optimization_options:optimization_options}}}control the optimization process; seldom used{p_end}

{p2coldent:+ {opt noh:eader}}suppress header table from above coefficient table{p_end}
{p2coldent:+ {opt not:able}}suppress coefficient table{p_end}
{synoptline}
{p2colreset}{...}
{p 4 6 2}
+ {opt noheader} and {opt notable} do not appear in the dialog box.{p_end}
{p 4 6 2}
The {it:depvar} and the {it:varlists} may contain time-series operators;
see {help tsvarlist}. {p_end}
{p 4 6 2}
{opt bootstrap}, {opt by}, {opt jackknife}, {opt rolling}, {opt statsby}, and
{opt xi} are allowed; see {help prefix}. {p_end}
{p 4 6 2}
{opt aweight}s and {opt fweight}s are allowed, see {help weight}.
{p_end}
{p 4 6 2}
See {help sureg postestimation} for features available after estimation.
{p_end}


{title:Description}

{pstd}
{opt sureg} fits seemingly unrelated regression models.
The acronyms SURE and SUR are often used for the estimator.

{title:Options}

{dlgtab:Model}

{phang}
{opt isure} specifies that {opt sureg} iterate over the estimated
disturbance covariance matrix and parameter estimates until the parameter
estimates converge.  Under seemingly unrelated regression, this iteration
converges to the maximum likelihood results.  If this option is not specified,
{opt sureg} produces two-step estimates.

{phang}
{opt constraints(constraints)}; see {help estimation options##constraints():estimation options}.

{dlgtab:df adj.}

{phang}
{opt small} specifies that small-sample statistics be computed.
It shifts the test statistics from chi-squared and Z statistics to F
statistics and t statistics.  While the standard errors from each equation are
computed using the degrees of freedom for the equation, the degrees of freedom
for the t statistics are all taken to be those for the first equation.

{phang}
{opt dfk} specifies the use of an alternate divisor in computing the
covariance matrix for the equation residuals.  As an asymptotically justified
estimator, {opt sureg} by default uses the number of sample observations (n)
as a divisor.  When the {opt dfk} option is set, a small-sample adjustment is
made and the divisor is taken to be sqrt((n - k_i) * (n - k_j)), where k_i and
k_j are the number of parameters in equations i and j respectively.

{phang}
{opt dfk2} specifies the use of an alternate divisor in computing the
covariance matrix for the equation residuals.  When the {opt dfk2} option is set,
the divisor is taken to be the mean of the residual degrees of freedom from
the individual equations.  

{dlgtab:Reporting}

{phang}
{opt level(#)}; see {help estimation options##level():estimation options}.

{phang}
{opt corr} displays the correlation matrix of the residuals between
equations and performs a Breusch-Pagan test for independent equations; that is,
the disturbance covariance matrix is diagonal.

{marker optimization_options}{...}
{dlgtab:Opt options}

{phang}
{it:optimization_options} control the iterative process that minimizes the 
    sum of squared errors when {opt isure} is specified.  These options are
    seldom used.

{phang2}
{opt iterate(#)} specifies the maximum number of iterations.  When the number
    of iterations equals {it:#}, the the optimizer stops and presents the
    current results, even if the convergence tolerance has not been reached.
    The default value of {opt iterate(#)} is the current value of 
    {helpb set maxiter}, which is {cmd:iterate(16000)} if {cmd:maxiter} has
    not been changed.

{phang2}
{opt trace} adds to the iteration log a display of the current parameter
    vector.

{phang2}
{opt nolog} prevents the iteration log from being shown.

{phang2}
{opt tol:erance(#)} specifies the tolerance for the coefficient vector.  When
the relative change in the coefficient vector from one iteration to the next
is less than or equal to {it:#} the optimization process is stopped.
{cmd:tolerance(1e-6)} is the default.

{pstd}
The following options are available with {opt sureg} but are not shown in the
dialog box:

{phang}
{opt noheader} suppresses display of the header reporting F statistics,
R-squared, and root mean squared error above the coefficient table.

{phang}
{opt notable} suppresses display of the coefficient table.


{title:Examples}

{p 8 12 2}{cmd:. sureg (price foreign weight length) (mpg foreign weight) (displ foreign weight)}

{pstd}
or, using global macros

{p 8 12 2}{cmd:. global price (price foreign weight length)}{p_end}
{p 8 12 2}{cmd:. global mpg   (mpg foreign weight)}{p_end}
{p 8 12 2}{cmd:. global displ (displ foreign weight)}

{p 8 12 2}{cmd:. sureg $price $mpg $displ}

{pstd}
To then test that the coefficients on foreign are 0 in all equations:

{p 8 28 2}{cmd:. test foreign} {space 6} (see {helpb test})

{pstd}
To test that the coefficients on foreign are 0 in the mpg and displ equations:

{p 8 12 2}{cmd:. test [mpg]foreign [displ]foreign}

{pstd}
To test an across-equation equality:

{p 8 12 2}{cmd:. test [price]foreign = [mpg]foreign}{p_end}
{p 8 12 2}{cmd:. test [displ]foreign = [mpg]foreign, accum}

{pstd}
To test a general linear combination:

{p 8 12 2}{cmd:. test [price]foreign-[mpg]weight = [displ]foreign - [displ]weight}


{title:Examples with options}

{phang}{cmd:. sureg (price foreign weight length) (mpg displ = foreign weight)}{p_end}
{phang}{cmd:. sureg (price foreign length) (mpg displ = foreign weight), isure}{p_end}
{phang}{cmd:. sureg (price foreign length) (mpg displ = foreign weight), isure corr}

{phang}{cmd:. constraint define 1 [price]foreign = [mpg]foreign}{p_end}
{phang}{cmd:. constraint define 2 [price]foreign = [displ]foreign}{p_end}
{phang}{cmd:. sureg (price foreign length) (mpg displ = foreign weight), const(1 2)}


{title:Also see}

{psee}
Manual:  {bf:[R] sureg}

{psee}
Online:  {help sureg postestimation};{break}
{helpb constraint},
{helpb ivreg},
{helpb mvreg},
{helpb reg3},
{helpb regress}
{p_end}