svy_estat.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
	svy_estat -- the estat dialog for svy estimation results

*!  VERSION 1.0.3  31mar2005

	NOTE: this dialog shares INCLUDE files with estat.dlg

*/

VERSION 9.0

INCLUDE _std_large
DEFINE _dlght 380
INCLUDE header

HELP hlp1, view("help svy_estat")
RESET res1

DIALOG main, tabtitle("Main") 	///
	label("estat -- Postestimation statistics for survey data")
BEGIN

  TEXT		tx_subcmd	_lft	_top	300	.,		///
	label("Reports and statistics: (subcommand)")
  LISTBOX	lb_subcmd	@	_ss	@	70,		///
	contents(main_subcmd_contents)					///
	values(main_subcmd_values)					///
	onselchangelist(main_subcmd_scripts)

  DEFINE holdy 110

  // note for -estat svyset-
  TEXT		tx_note		_lft	holdy	_iwd	.,		///
  	label("Click OK or Submit to display the estimation's survey design characteristics")

  // expression for -estat lceffects-
  TEXT		tx_exp		_lft	holdy	_iwd	.,		///
		label("Linear expression:")
  EDIT		ed_exp		@	_ss	@	.,		///
		label("Linear expression")

  // options for -estat effects- and -estat lceffects-
  GROUPBOX	gb_eff		_lft	holdy	_iwd	_ht18,		///
	label("Effect measures (by default all available are reported)")

  GROUPBOX	gb_def		_indent	_ss	_inwd	_ht7,		///
	label("Design-effects")
DEFINE holdy2 @y
  CHECKBOX	ck_deff		_indent	_ss	_inwd	.,		///
	label("Report DEFF")						///
	option(deff)
  CHECKBOX	ck_deft		@	_ms	@	.,		///
	label("Report DEFT")						///
	option(deft)
  CHECKBOX	ck_srs		@	_ms	@	.,		///
	label("Report design effects assuming SRS within subpopulation") ///
	option(srssubpop)

  GROUPBOX	gb_mef		_ilft	300   	_ibwd 	_ht4h,		///
	label("Misspecification-effects")
  CHECKBOX	ck_meff		_indent	_ss	_inwd	.,		///
	label("Report MEFF")						///
	option(meff)
  CHECKBOX	ck_meft		@	_ms	@	.,		///
	label("Report MEFT")						///
	option(meft)

  // options for -estat size-
  GROUPBOX	gb_size		_lft	holdy	_iwd	_ht4h,		///
	label("Subpopulation sizes (by default all are reported)")
  CHECKBOX	ck_obs		_indent	_ss	_inwd	.,		///
	option(obs)							///
	label("Report number of observations (within subpopulation)")
  CHECKBOX	ck_size		@	_ms	@	.,		///
	label("Report subpopulation sizes")				///
	option(size)

  INCLUDE estat_vce
END

INCLUDE estat_vce_pr

SCRIPT PREINIT
BEGIN
	create STRING svy_estat_current_subcmd
END

LIST main_subcmd_contents
BEGIN
	"Survey design characteristics"
	"DEFF and MEFF for point estimates"
	"DEFF and MEFF for linear combinations"
	"Subpopulation sizes"
	"Display covariance matrix estimates"
END

LIST main_subcmd_values
BEGIN
	svyset
	effects
	lceffects
	size
	vce
END

LIST main_subcmd_scripts
BEGIN
	script sel_svyset
	script sel_effects
	script sel_lceffects
	script sel_size
	script sel_vce
END

SCRIPT sel_svyset
BEGIN
	svy_estat_current_subcmd.setstring "svyset"
	main.tx_note.show
	main.tx_exp.hide
	main.ed_exp.hide
	script deffmeff_hide
	script size_hide
	program vce_off
END

SCRIPT sel_effects
BEGIN
	svy_estat_current_subcmd.setstring "effects"
	main.tx_note.hide
	main.tx_exp.hide
	main.ed_exp.hide
	script move_effects
	script deffmeff_show
	script size_hide
	program vce_off
END

SCRIPT sel_lceffects
BEGIN
	svy_estat_current_subcmd.setstring "lceffects"
	main.tx_note.hide
	main.tx_exp.show
	main.ed_exp.show
	script move_lceffects
	script deffmeff_show
	script size_hide
	program vce_off
END

SCRIPT sel_size
BEGIN
	svy_estat_current_subcmd.setstring "size"
	main.tx_note.hide
	main.tx_exp.hide
	main.ed_exp.hide
	script deffmeff_hide
	script size_show
	program vce_off
END

SCRIPT sel_vce
BEGIN
	svy_estat_current_subcmd.setstring "vce"
	main.tx_note.hide
	main.tx_exp.hide
	main.ed_exp.hide
	script deffmeff_hide
	script size_hide
	program vce_on
END

SCRIPT move_effects
BEGIN
	main.gb_eff.setposition		. 110 . .
	main.gb_def.setposition		. 130 . .
	main.ck_deff.setposition	. 150 . .
	main.ck_deft.setposition	. 175 . .
	main.ck_srs.setposition		. 200 . .
	main.gb_mef.setposition		. 235 . .
	main.ck_meff.setposition	. 255 . .
	main.ck_meft.setposition	. 280 . .
END

SCRIPT move_lceffects
BEGIN
	main.gb_eff.setposition		. 160 . .
	main.gb_def.setposition		. 180 . .
	main.ck_deff.setposition	. 200 . .
	main.ck_deft.setposition	. 225 . .
	main.ck_srs.setposition		. 250 . .
	main.gb_mef.setposition		. 285 . .
	main.ck_meff.setposition	. 305 . .
	main.ck_meft.setposition	. 330 . .
END

SCRIPT deffmeff_hide
BEGIN
	main.gb_eff.hide
	main.gb_def.hide
	main.ck_deff.hide
	main.ck_deft.hide
	main.ck_srs.hide
	main.gb_mef.hide
	main.ck_meff.hide
	main.ck_meft.hide
END

SCRIPT deffmeff_show
BEGIN
	main.gb_eff.show
	main.gb_def.show
	main.ck_deff.show
	main.ck_deft.show
	main.ck_srs.show
	main.gb_mef.show
	main.ck_meff.show
	main.ck_meft.show
END

SCRIPT size_hide
BEGIN
	main.gb_size.hide
	main.ck_obs.hide
	main.ck_size.hide
END

SCRIPT size_show
BEGIN
	main.gb_size.show
	main.ck_obs.show
	main.ck_size.show
END

PROGRAM vl_eq_output
BEGIN
	put main.vl_eq
END

PROGRAM command
BEGIN
	put "estat"
	put " " main.lb_subcmd
	if svy_estat_current_subcmd.equals("lceffects") {
		require main.ed_exp
		put " " main.ed_exp
	}
	beginoptions
		// -estat [lc]effects-
		option main.ck_deff
		option main.ck_deft
		option main.ck_srs
		option main.ck_meff
		option main.ck_meft

		// -estat size-
		option main.ck_obs
		option main.ck_size
		put " " /program vce_output
	endoptions
END