spearman.hlp

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

{smcl}
{* 18mar2005}{...}
{cmd:help spearman}, {cmd:help ktau}{right:dialogs:  {bf:{dialog spearman}}  {bf:{dialog ktau}}}
{hline}

{title:Title}

{p2colset 5 21 23 2}{...}
{synopt:{hi:[R] spearman} {hline 2}}Spearman's and Kendall's
correlations{p_end}
{p2colreset}{...}


{title:Syntax}

{phang}
Spearman's rank correlation coefficients

{p 8 17 2}
{cmd:spearman}
[{varlist}]
{ifin}
[{cmd:,} {it:{help spearman##spearman_options:spearman_options}}]

{phang}
Kendall's rank correlation coefficients

{p 8 13 2}
{cmd:ktau}
[{varlist}]
{ifin}
[{cmd:,} {it:{help spearman##ktau_options:ktau_options}}]

{marker spearman_options}{...}
{synoptset 24 tabbed}{...}
{synopthdr:spearman_options}
{synoptline}
{syntab:Main}
{synopt:{cmd:stats(}{it:{help spearman##spearman_list:spearman_list}}{cmd:)}}list
of statistics; select up to 3 statistics; default is {cmd:stats(rho)}{p_end}
{synopt:{opt p:rint(#)}}significance level for displaying coefficients{p_end}
{synopt:{opt st:ar(#)}}significance level for displaying with a star{p_end}
{synopt:{opt b:onferroni}}use Bonferroni-adjusted significance level{p_end}
{synopt:{opt sid:ak}}use Sidak-adjusted significance level{p_end}
{synopt:{opt pw}}calculate all the pairwise correlation coefficients between
the variables{p_end}
{synopt:{opt mat:rix}}display output in matrix form{p_end}
{synoptline}

{marker ktau_options}{...}
{synopthdr:ktau_options}
{synoptline}
{syntab:Main}
{synopt:{cmd:stats(}{it:{help spearman##ktau_list:ktau_list}}{cmd:)}}list
of statistics; select up to 6 statistics; default is {cmd:stats(taua)}{p_end}
{synopt:{opt p:rint(#)}}significance level for displaying coefficients{p_end}
{synopt:{opt st:ar(#)}}significance level for displaying with a star{p_end}
{synopt:{opt b:onferroni}}use Bonferroni-adjusted significance level{p_end}
{synopt:{opt sid:ak}}use Sidak-adjusted significance level{p_end}
{synopt:{opt pw}}calculate all the pairwise correlation coefficients between
the variables{p_end}
{synopt:{opt mat:rix}}display output in matrix form{p_end}
{synoptline}
{p2colreset}{...}
{p 4 6 2}
{opt by} may be used with {opt spearman} and {opt ktau};
see {helpb by}.{p_end}

{p 4 6 2}
{marker spearman_list}{...}
where the elements of {it:spearman_list} may be

{p 8 25 2}{cmd:rho}{space 5} correlation coefficient{p_end}
{p 8 25 2}{cmd:obs}{space 5} number of observations{p_end}
{p 8 25 2}{cmd:p}{space 7} significance level

{p 6 6 2}
{marker ktau_list}{...}
and the elements of {it:ktau_list} may be

{p 8 25 2}{cmd:taua}{space 4} correlation coefficient tau_a{p_end}
{p 8 25 2}{cmd:taub}{space 4} correlation coefficient tau_b{p_end}
{p 8 25 2}{cmd:score}{space 3} score{p_end}
{p 8 25 2}{cmd:se}{space 6} standard error of score{p_end}
{p 8 25 2}{cmd:obs}{space 5} number of observations{p_end}
{p 8 25 2}{cmd:p}{space 7} significance level 


{title:Description}

{pstd}
{opt spearman} displays Spearman's rank correlation coefficients for all pairs
  of variables in {varlist} or, if {it:varlist} is not specified, all the
  variables in the dataset.

{pstd}
{opt ktau} displays Kendall's rank correlation coefficients between
  the variables in {varlist} or, if {it:varlist} is not specified, all the
  variables in the dataset.  {opt ktau} is intended for use on small and
  moderate-sized datasets; it requires considerable computation time for
  larger datasets.


{title:Options for spearman}

{dlgtab:Main}

{phang}
{cmd:stats(}{it:{help spearman##spearman_list:spearman_list}}{cmd:)}
  specifies the statistics to be displayed in the matrix of output.
  {cmd:stats(rho)} is the default.  Up to 3 statistics may be specified,
  {cmd:stats(rho obs p)} would display the correlation coefficient, 
  number of observations, and significance level.  If {it:varlist} contains
  only two variables, all statistics are shown in tabular form, and 
  {cmd:stats()}, {cmd:print()}, and {cmd:star()} have no effect unless the
  {cmd:matrix} option is specified.

{phang}
{opt print(#)} specifies the significance level of correlation coefficients to
  be printed.  Correlation coefficients with larger significance levels are left
  blank in the matrix.  Typing {cmd:spearman, print(.10)} would list only those
  correlation coefficients that are significant at the 10% level or lower.

{phang}
{opt star(#)} specifies the significance level of correlation coefficients to
  be marked with a star.  Typing {cmd:spearman, star(.05)} would "star" all
  correlation coefficients significant at the 5% level or lower.

{phang}
{opt bonferroni} makes the Bonferroni adjustment to calculated significance
  levels.  This affects printed significance levels and the {opt print()} and
  {opt star()} options.  Thus {cmd:spearman, print(.05) bonferroni} prints
  coefficients with Bonferroni-adjusted significance levels of .05 or less.

{phang}
{opt sidak} makes the Sidak adjustment to calculated significance
  levels.  This affects printed significance levels and the {opt print()} and
  {opt star()} options.  Thus {cmd:spearman, print(.05) sidak} prints
  coefficients with Sidak-adjusted significance levels of .05 or less.

{phang}
{opt pw} specifies that correlations be calculated using pairwise deletion of
  observations with missing values.  By default, {opt spearman}
  uses casewise deletion, where observations are ignored if any of the specified
  variables in {it:varlist} are missing.

{phang}
{opt matrix} forces {cmd:spearman} to display the statistics as a matrix, 
even if {it:varlist} contains only two variables.  {cmd:matrix} is 
implied if more than two variables are specified.


{title:Options for ktau}

{dlgtab:Main}

{phang}
{cmd:stats(}{it:{help spearman##ktau_list:ktau_list}}{cmd:)}
specifies the statistics to be displayed in the matrix of output.  
{cmd:stats(tau)} is the default.  Up to 6 statistics may be specified.
{cmd:stats(taua taub score se obs p)} would display the tau_a, tau_b, score,
standard error of score, number of observations, and significance level.
If {it:varlist} contains only two variables, all statistics are shown in
tabular form and {cmd:stats()}, {cmd:print()}, and {cmd:star()} have no effect
unless the {cmd:matrix} option is specified.

{phang}
{opt print(#)} specifies the significance level of correlation coefficients to
  be printed.  Correlation coefficients with larger significance levels are left
  blank in the matrix.  Typing {cmd:ktau, print(.10)} would list only those
  correlation coefficients that are significant at the 10% level or lower.

{phang}
{opt star(#)} specifies the significance level of correlation coefficients to
  be marked with a star.  Typing {cmd:ktau, star(.05)} would "star" all
  correlation coefficients significant at the 5% level or lower.

{phang}
{opt bonferroni} makes the Bonferroni adjustment to calculated significance
  levels.  This affects printed significance levels and the {opt print()} and
  {opt star()} options.  Thus {cmd:ktau, print(.05) bonferroni} prints
  coefficients with Bonferroni-adjusted significance levels of .05 or less.

{phang}
{opt sidak} makes the Sidak adjustment to calculated significance
  levels.  This affects printed significance levels and the {opt print()} and
  {opt star()} options.  Thus {cmd:ktau, print(.05) sidak} prints coefficients
  with Sidak-adjusted significance levels of .05 or less.

{phang}
{opt pw} specifies that correlations be calculated using pairwise deletion of
  observations with missing values.  By default, {opt ktau}
  uses casewise deletion, where observations are ignored if any of the specified
  variables are missing.

{phang}
{opt matrix} forces {cmd:ktau} to display the statistics as a matrix, even if
{it:varlist} contains only two variables.  {cmd:matrix} is implied
if more than two variables are specified.


{title:Examples}

{phang}{cmd:. spearman price weight, matrix}{p_end}
{phang}{cmd:. spearman price weight mpg displ, stats(obs p) pw}{p_end}
{phang}{cmd:. spearman price weight mpg displ, stats(rho p) bon}{p_end}
{phang}{cmd:. ktau price weight mpg displ, stats(taua taub score se p obs) star(.05)}{p_end}
{phang}{cmd:. ktau price weight mpg displ, star(.05) bon}{p_end}
{phang}{cmd:. ktau price weight mpg displ, print(.05) star(.01) bon}{p_end}
{phang}{cmd:. ktau price weight mpg disp, stats(taub obs p score se)}


{title:Also see}

{psee}
Manual:  {bf:[R] spearman}

{psee}
Online:  {helpb correlate}, {helpb nptrend}
{p_end}