svy_nbreg.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  svy: nbreg

*! VERSION 1.1.2  15mar2005

  keyword:  eclass

*/

VERSION 9.0

INCLUDE _std_large
INCLUDE _ht330
INCLUDE header

HELP hlp1, view("help svy: nbreg")
RESET res1

DIALOG main, tabtitle("Model") ///
	label("svy: nbreg - Negative binomial regression for survey data")
BEGIN
  INCLUDE _dviv

  CHECKBOX ck_nocons @         _ms       @         .,		///
	label("Suppress constant term")				///
	option(noconstant)

  GROUPBOX gb_disper _lft      _ls       _iwd      _ht2,	///
	label("Parameterization of dispersion")

  RADIO    rb_mean   _ilft     _ss       _cwd2     .,		///
	label("Function of the expected mean")			///
	first
  RADIO    rb_cons   _lft2     @         @         .,		///
	label("Constant") last option(dispersion(constant))

  GROUPBOX gb_opt    _lft      _xls      _iwd      _ht10,	///
	label("Options")

  RADIO    rb_expose _ilft     _ss       _cwd3_2   .,		///
	label("Exposure variable:")				///
	first							///
	onclickon(script expose)
  RADIO    rb_offset _lft3_2   @         @         .,		///
	label("Offset variable:")				///
	last							///
	onclickon(script offset)

  VARNAME  vn_expose _ilft     _ss       @         .,		///
	label("Exposure variable")				///
	option(exposure)

  VARNAME  vn_offset _lft3_2   @         @         .,		///
	label("Offset variable")				///
	option(offset)

  DEFINE _x _ilft
  DEFINE _cx _ibwd
  DEFINE _y _ls
  INCLUDE _constraints

  DEFINE _x _xsetbu
  DEFINE _y 300
  INCLUDE _bu_svyset

END

SCRIPT expose
BEGIN
	  main.vn_expose.enable
	  main.vn_offset.disable
END

SCRIPT offset
BEGIN
	  main.vn_expose.disable
	  main.vn_offset.enable
END

INCLUDE svy_subpop_model
INCLUDE svy_se
INCLUDE svy_rpt
INCLUDE max_ml

SCRIPT POSTINIT
BEGIN
	script svy_rpt_setViewAsIRR
	script max_setDefaultNoLog
END

PROGRAM svy_options
BEGIN
	beginoptions
		put " " /program svy_subpop_output
		put " " /program svy_se_output
		put " " /program svy_rpt_output
	endoptions
END

PROGRAM command
BEGIN
	allowxi
	put "svy"
	put /program svy_options
	put ": nbreg "
	varlist main.vn_dv [main.vl_iv]
	if !main.vl_iv & main.ck_nocons {
		stopbox stop ///
`""Suppress constant term" is selected without independent variables."'
	}
	if subpop.ck_ifin {
		put " " /program ifin_output
	}
	beginoptions
		option main.ck_nocons
		option main.rb_cons
		optionarg main.vn_expose
		optionarg main.vn_offset
		INCLUDE _constraints_main_pr
		put " " /program svy_rpt_cmdoutput
		put " " /program max_output
	endoptions
END