svy_intreg.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  svy: intreg

*!  VERSION 1.1.3  21mar2005

  keyword:  eclass

*/

VERSION 9.0

INCLUDE _std_large
INCLUDE _ht340
INCLUDE header

HELP hlp1, view("help svy: intreg")
RESET res1

DIALOG main, tabtitle("Model") ///
	label("svy: intreg - Interval regression for survey data")
BEGIN
  TEXT     tx_dv1    _lft      _topph    _vnwd     .,			/*
		*/ label("Dependent variable 1:")			/*
		*/
  VARNAME  vn_dv1    @         _ss       @         .,			/*
		*/ label("Dependent variable 1")			/*
		*/

  TEXT     tx_dv2    _vlx      _topph    @         .,			/*
		*/ label("Dependent variable 2:")			/*
		*/
  VARNAME  vn_dv2    @         _ss       @         .,			/*
		*/ label("Dependent variable 2")			/*
		*/

  TEXT     tx_iv     _lft      _ls       _iwd      .,			/*
		*/ label("Independent variables:")			/*
		*/
  VARLIST  vl_iv     @         _ss       @         .,			/*
		*/ label("Independent variables")			/*
		*/ allowcat						/*
		*/
  CHECKBOX ck_nocons @         _ms       _cwd1     .,			/*
		*/ label("Suppress constant term")			/*
		*/ option("noconstant")					/*
		*/

  GROUPBOX gb_output _lft      _ls       _iwd      _ht15h,		/*
		*/ label("Options")					/*
		*/
  CHECKBOX ck_het    _ilft     _ss       _ibwd     _ht2h,		/*
  		*/ groupbox						/*
		*/ label("Independent variables to model the variance")	/*
		*/ clickon("script het_on")				/*
		*/ clickoff("script het_off")
  VARLIST  vl_het    _indent   _ms       _cwd2          .,		/*
		*/ label("Independent variables to model the variance")	/*
		*/ allowcat
  CHECKBOX ck_nocon  _ilft2    @         _cwd5              .,		/*
		*/ label("Suppress constant term")			/*
		*/ option(noconstant)
  TEXT     tx_offset _ilft     _xls      _vnwd     .,			/*
		*/ label("Offset variable:")				/*
		*/
  VARNAME  vn_offset @         _ss       _vnwd     .,			/*
		*/ label("Offset variable")				/*
		*/ option("offset")					/*
		*/
  DEFINE _x _ilft
  DEFINE _cx _ibwd
  DEFINE _y _ls
  INCLUDE _constraints

  DEFINE _x _xsetbu
  DEFINE _y 340
  INCLUDE _bu_svyset

END

SCRIPT het_on
BEGIN
	main.vl_het.enable
	main.ck_nocon.enable
END

SCRIPT het_off
BEGIN
	main.vl_het.disable
	main.ck_nocon.disable
END

INCLUDE svy_subpop_model
INCLUDE svy_se
INCLUDE svy_rpt
INCLUDE max_ml

SCRIPT POSTINIT
BEGIN
	script svy_rpt_setViewAsNoEform
	script max_setDefaultNoLog
END

PROGRAM svy_options
BEGIN
	beginoptions
		put " " /program svy_subpop_output
		put " " /program svy_se_output
		put " " /program svy_rpt_output
	endoptions
END

PROGRAM het_output
BEGIN
	require main.vl_het
	put main.vl_het
	beginoptions
		option main.ck_nocon
	endoptions
END

PROGRAM command
BEGIN
	allowxi
	put "svy"
	put /program svy_options
	put ": intreg "
	varlist main.vn_dv1 main.vn_dv2 [main.vl_iv]
	if !main.vl_iv & main.ck_nocons {
		stopbox stop ///
`""Suppress constant term" is selected without independent variables."'
	}
	if subpop.ck_ifin {
		put " " /program ifin_output
	}
	beginoptions
		option main.ck_nocons
		if main.ck_het {
			put "het("
			put /program het_output
			put ")"
		}
		optionarg main.vn_offset
		INCLUDE _constraints_main_pr
		put " " /program svy_rpt_cmdoutput
		put " " /program max_output
	endoptions
END