stcox_estat.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  stcox_estat

*!  VERSION 1.0.3  31mar2005

*/

VERSION 9.0

INCLUDE _std_large
DEFINE _dlght 360
INCLUDE header

HELP hlp1, view("help stcox postestimation")
RESET res1

DIALOG main, label("estat - Postestimation statistics") tabtitle("Main")
BEGIN
  TEXT     tx_subcmd		_lft	_top	_iwd	.,		///
  	label("Reports and statistics: (subcommand)")
  LISTBOX  lb_subcmd		@	_ss	@	70,		///
  	contents(main_subcommand_contents)				///
  	values(main_subcommand_values)					///
  	onselchangelist(main_subcommand_scripts)

  DEFINE holdy 110
  // Information criteria
  TEXT     tx_icnote		_lft	holdy	_iwd	.,		///
  	label(`"Click "OK" or "Submit" to display the AIC and BIC information criteria"')
  // Summarize options
  GROUPBOX gb_eqlist            _lft    holdy	_iwd	_ht6,		///
  	label("Summarize")
  RADIO    rb_default		_ilft	_ss	_inwd	.,		///
  	first label("Use all variables involved in the estimation")	///
  	onclickon(main.vl_spec.disable)
  RADIO    rb_spec		@	_ss	@	.,		///
	onclickon(main.vl_spec.enable) last				///
	label("Use variables and optional equation names:")
  VARLIST  vl_spec	      _indent2	_ss	_inwd	.,		///
	label("Use variables and optional equation names")
  CHECKBOX ck_equation      	_lft	+45	_iwd	.,		///
	option(equation)						///
	label("Display summary by equation")
  CHECKBOX ck_labels		@	_ms	@	.,		///
  	label("Display variable labels")				///
  	option(labels)
  CHECKBOX ck_noheader		_lft	_ms	_iwd	.,		///
	option(noheader)						///
	label("Suppress the header")
  CHECKBOX ck_noweights		@	_ms	@	.,		///
	option(noweights)						///
	label("Ignore weights")

  INCLUDE estat_vce

  // concordance options
  GROUPBOX gb_option		_lft	holdy	_iwd	_ht4,		///
	label("Sample")
  RADIO    rb_default2		_ilft	_ss	_inwd	.,		///
	first label("Use the sample from the stcox regression, e(sample)")
  RADIO    rb_all		@	_ss	@	.,		///
	label("Use all available data") option(all) last

  CHECKBOX ck_noshow		_lft	+45	_iwd	.,		///
	label("Suppress st variable description") option(noshow)

  // phtest options
  TEXT     tx_phtest1		_lft 	holdy	_iwd	.,		///
  	label(`"Click "OK" or "Submit" to Test proportional-hazards assumption using default settings."')
  TEXT     tx_phtest2		@	_ss 	@	.,		///
  	label(`"Click "Test proportional-hazards assumption" to launch a dialog box with all options."')

  BUTTON   bu_phtest		_lft	_ls	_cwd1	.,		///
  	onpush(view dialog stcox_estat_phtest) 				///
  	label(`"Test proportional-hazards assumption"')

  INCLUDE _estat_bootstrap
END

INCLUDE _estat_bootstrap_pr
INCLUDE estat_vce_pr

LIST main_subcommand_contents
BEGIN
 	 "Harrell's C index (concordance)"
 	 "Proportional hazard assumptions based on Schoenfeld residuals (phtest)"
 	 "Information criteria (ic)"
 	 "Summarize estimation sample (summarize)"
 	 "Covariance matrix estimates (vce)"
END

LIST main_subcommand_values
BEGIN
	concordance
	phtest
	ic
	summarize
	vce
END

LIST main_subcommand_scripts
BEGIN
	script sel_concordance
	script sel_phtest
	script sel_ic
	script sel_summarize
	script sel_vce
END

SCRIPT sel_ic
BEGIN
	script main_hide_all
	main.tx_icnote.show
END

SCRIPT sel_summarize
BEGIN
	script main_hide_all
	script main_summ_on
END

SCRIPT sel_vce
BEGIN
	script main_hide_all
	program vce_on
END

SCRIPT sel_concordance
BEGIN
	script main_hide_all
	script main_concordance_on
	script ifin_enable
END

SCRIPT sel_phtest
BEGIN
	script main_hide_all
	script main_phtest_on
END

SCRIPT main_summ_on
BEGIN
	main.ck_equation.show
	main.ck_labels.show
	main.ck_noheader.show
	main.ck_noweights.show
	main.gb_eqlist.show
	main.rb_default.show
	main.rb_spec.show
	main.vl_spec.show
END
SCRIPT main_summ_off
BEGIN
	main.ck_equation.hide
	main.ck_labels.hide
	main.ck_noheader.hide
	main.ck_noweights.hide
	main.gb_eqlist.hide
	main.rb_default.hide
	main.rb_spec.hide
	main.vl_spec.hide
END

SCRIPT main_concordance_on
BEGIN
	main.gb_option.show
	main.rb_default2.show
	main.rb_all.show
	main.ck_noshow.show
END
SCRIPT main_concordance_off
BEGIN
	main.gb_option.hide
	main.rb_default2.hide
	main.rb_all.hide
	main.ck_noshow.hide
END

SCRIPT main_phtest_on
BEGIN
	main.tx_phtest1.show
	main.tx_phtest2.show
  	main.bu_phtest.show
END
SCRIPT main_phtest_off
BEGIN
	main.tx_phtest1.hide
	main.tx_phtest2.hide
  	main.bu_phtest.hide
END

PROGRAM vl_output
BEGIN
	put main.vl_spec
END

PROGRAM vl_eq_output
BEGIN
	put main.vl_eq
END

SCRIPT main_hide_all
BEGIN
	main.tx_icnote.hide
	script main_summ_off
	program vce_off
	script main_concordance_off
	script main_bootstrap_hide
	script ifin_disable
	script main_phtest_off
END

INCLUDE ifin

PROGRAM command
BEGIN
	put "estat "
	put main.lb_subcmd

	if main.rb_spec {
		require main.vl_spec
		put " " main.vl_spec
	}
	INCLUDE _ifin_pr
	beginoptions
		// concordance options
		option main.rb_all
		option main.ck_noshow

		// Summarize options
		option main.ck_equation
		option main.ck_labels
		option main.ck_noheader
		option main.ck_noweights

		put " " /program vce_output
		put " " /program bootstrap_output
	endoptions
END