svy_jackknife.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  svy jackknife

*!  VERSION 1.0.8  25mar2005

*/

VERSION 9.0

INCLUDE _std_large
INCLUDE _ht320
INCLUDE header

HELP hlp1, view("help svy jackknife")
RESET res1

DIALOG main, tabtitle("Main") ///
	label("svy jackknife - Jackknife estimation for survey data")
BEGIN
  DEFINE _y _top
  INCLUDE _cmd_exp_list

  GROUPBOX gb_n      _lft      _xls     _iwd      _ht8,			///
	label("Where are the number of observations used in the calculation stored?")

  RADIO    rb_empty  _indent   _ss       _inwd     .,			///
	first								///
	label("Automatically determined by jackknife")			///
	onclickon(main.ed_n.disable)					///
	option(NONE)
  RADIO    rb_eclass @         _ss       @         .,			///
	label("Saved in e(N)")						///
	onclickon(main.ed_n.disable)					///
	option(eclass)
  RADIO    rb_rclass @         _ss       @         .,			///
	label("Saved in r(N)")						///
	onclickon(main.ed_n.disable)					///
	option(rclass)
  RADIO    rb_n      @         _ss       _cwd2     .,			///
	last 								///
	label("User-specified alternative:")				///
	onclickon(main.ed_n.enable)					///
	option(NONE)
		*/
  EDIT     ed_n      _lft2     @         @         .,			///
	label("User-specified alternative") option(n)

  DEFINE _x _xsetbu
  DEFINE _y 290
  INCLUDE _bu_svyset

END

INCLUDE svy_subpop_model

DIALOG opt, tabtitle("Options")
BEGIN
  DEFINE _y _top
  INCLUDE _saving

  CHECKBOX ck_keep   _lft     _xxls      _cwd1     .,			///
		label("Keep pseudovalues")				///
		option(keep)
  CHECKBOX ck_mse    @         _ms       @         .,			///
		label("Use MSE formula for the variance")		///
		option(mse)

END

INCLUDE _saving_sc

DIALOG report, tabtitle("Reporting")
BEGIN
  DEFINE _x _lft
  DEFINE _cx _spr
  DEFINE _y _top
  INCLUDE _sp_level

  CHECKBOX ck_noheader _lft    _ls       _cwd1     .,			///
		label("Suppress the table header")			///
		clickon(program check_header)				///
		clickoff(program check_header)				///
		option("noheader")
  CHECKBOX ck_nolegend @       _ms       @         .,			///
		label("Suppress the table legend")			///
		clickon(program check_legend)				///
		clickoff(program check_legend)				///
		option("nolegend")
  CHECKBOX ck_verbose  @       _ms       @         .,			///
		label("Display the full table legend")			///
		option("verbose")
  CHECKBOX ck_noadjust @       _ms       @         .,			///
		label("Do not adjust model's Wald statistic")		///
		option(noadjust)


  TEXT     tx_title  _lft      _ls       _iwd      .,			///
		label("Title:")
  EDIT     ed_title  @         _ss       @         .,			///
		label("Title") option(title)

  DEFINE _x _lft2
  DEFINE _cx _cwd1
  DEFINE _y _top
  DEFINE _cy _ht8
  INCLUDE _output_reps
END

PROGRAM check_header
BEGIN
	if report.ck_noheader {
		call gaction report.ck_nolegend.disable
		call gaction report.ck_verbose.disable
	}
	if !report.ck_noheader {
		call gaction report.ck_nolegend.enable
		call program check_legend
	}
END

PROGRAM check_legend
BEGIN
	if report.ck_nolegend {
		call gaction report.ck_verbose.disable
	}
	if !report.ck_nolegend {
		call gaction report.ck_verbose.enable
	}
END

DIALOG adv, tabtitle("Advanced")
BEGIN
  CHECKBOX ck_nodrop _lft      _top      _iwd      .,			///
	label("Do not drop observations")				///
	option(nodrop)

  TEXT     tx_reject @         _ls       _iwd      .,			///
	label("Identify invalid results:")
  EDIT     ed_reject @         _ss       @         .,			///
	label("Identify invalid results")				///
	option(reject)
END

PROGRAM jknife_options
BEGIN
	put "svy jackknife "
	option main.ck_b
	option main.ck_se
	put " " main.ed_explst
 	put " " /program ifin_output
	beginoptions
		option radio(main rb_empty rb_rclass rb_eclass rb_n)
		if main.rb_n {
			require main.ed_n
			optionarg main.ed_n
		}
		put " " /program svy_subpop_output
		put " "
		INCLUDE _saving_pr
		option opt.ck_keep
		option opt.ck_mse
		INCLUDE _level_report_pr
		option report.ck_noheader
		option report.ck_nolegend
		option report.ck_verbose
		option report.ck_noadjust
		option radio(report rb_qui rb_dots rb_noi rb_trace)
		optionarg report.ed_title
		option adv.ck_nodrop
		optionarg adv.ed_reject
	endoptions
END

PROGRAM command
BEGIN
	put /program jknife_options
	put " " " : "	/* end of prefix, begin command */
		require main.vl_cmd
		put main.vl_cmd
END