svmat.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
	svmat
	
	VERSION 1.0.0  21dec2002
*/

VERSION 8.0

INCLUDE _std_medium
INCLUDE _ht280
INCLUDE header

HELP hlp1, view("help svmat")
RESET res1

DIALOG main,label("svmat - Convert matrix to variables")                /*
		*/ tabtitle("Main")
BEGIN
  TEXT     tx_matname     _lft     _top     _iwd        .,              /*
                */ label("Matrix name:")                

  COMBOBOX cb_matname     _lft     _ss      _iwd        .,              /*
                */ label("")                                            /*
                */ contents(matrix)                                     /*
                */ dropdown                                             /*
                */ error("Matrix name")
  
  GROUPBOX gb_name       _lft      _xls     _iwd        _ht12,          /*
                */ label("Name new variables")                        

  RADIO    rb_default    _indent   _ss      _inwd       .,              /*
    */ label("Use matrix name suffixed by number (starting from 1)")    /*
                */ first                                                /*
                */ clickon("gaction main.ed_string.disable")            /*
                */ option(NONE)
  RADIO    rb_col        @         _ss      @           .,              /*
                */ label("Use column names")                            /*
                */ clickon("gaction main.ed_string.disable")            /*
                */ option(col)

  RADIO    rb_eqcol      @         _ss      @           .,              /*
                */ label("Use equation names prefixed to column names") /*
                */ clickon("gaction main.ed_string.disable")            /*
                */ option(eqcol)

  RADIO    rb_matcol     @         _ss      @           .,              /*
                */ label("Use matrix names prefixed to column names")   /*
                */ clickon("gaction main.ed_string.disable")            /*
                */ option(matcol)

  RADIO    rb_string     @         _ss      @           .,              /*
*/label("Use the following prefix:  (suffixed by number starting from 1)")/*
                */ last                                                 /*
                */ clickon("gaction main.ed_string.enable")             /*
                */ option(NONE)

  EDIT     ed_string     _indent2  _ss      _vnwd        .,             /*
		*/ label("Use the following prefix")			/*
                */ max(32)

  DEFINE  _x  _lft
  DEFINE  _y  _xls
  DEFINE  _cx _iwd
  INCLUDE _type
END

INCLUDE _type_list_all

PROGRAM command
BEGIN
	require main.cb_matname 
	put "svmat "
	INCLUDE _type_pr
	put main.cb_matname
	beginoptions
		if !main.rb_default {
			put "names("
			option radio(main rb_default rb_col rb_eqcol /*
					*/ rb_matcol rb_string)
			if main.rb_string {
				require main.ed_string
				put main.ed_string
			}
			put ")"
		}
	endoptions
END